vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v2.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2014
 
zurück
Rubrik: Windows/System28.07.01
GetLocalTime-Funktion

Ermittelt das aktuelle Datum und die aktuelle Systems-Zeit.

Betriebssystem:  Win95, Win98, WinNT 3.1, Win2000, WinMEViews:  5.249 

Deklaration:

Declare Sub GetLocalTime Lib "kernel32.dll" (lpSystemTime As SYSTEMTIME)

Beschreibung:
Ermittelt das aktuelle Datum und die aktuelle Systems-Zeit.

Parameter:
lpSystemTimeErwartet eine SYSTEMTIME-Struktur die mit den Zeitangaben gefüllt wird.

Rückgabewert:
keiner


Beispiel:

' Fügen Sie nachfolgenden Code in ein öffengtliches Modul ein
Private Declare Sub GetLocalTime Lib "kernel32.dll" (lpSystemTime As SYSTEMTIME)
 
Private Declare Function SetTimer Lib "user32.dll" ( _
  ByVal hWnd As Long, _
  ByVal nIDEvent As Long, _
  ByVal uElapse As Long, _
  ByVal lpTimerFunc As Long) As Long
 
Private Declare Function KillTimer Lib "user32.dll" ( _
  ByVal hWnd As Long, _
  ByVal nIDEvent As Long) As Long
 
Const WM_TIMER = &H113 ' Timer-Ereignis trifft ein
 
Private Type SYSTEMTIME
  wYear As Integer
  wMonth As Integer
  wDayOfWeek As Integer
  wDay As Integer
  wHour As Integer
  wMinute As Integer
  wSecond As Integer
  wMilliseconds As Integer
End Type
 
Private hEvent As Long
' Timer-Prozedur, welche im Abstand der festgelegten
' Millisekunden ein Ereignis sendet
Public Sub TimerProc(ByVal hWnd As Long, ByVal uMsg As Long, _
  ByVal wParam As Long, ByVal lParam As Long)
 
  Dim ST As SYSTEMTIME
 
  If uMsg = WM_TIMER Then
    ' Lokale Zeit ermitteln...
     GetLocalTime ST
 
    ' ... und im Labelfeld der Form anzeigen
    Form1.Label1.Caption = Format$(ST.wHour, "00:") & _
      Format$(ST.wMinute, "00:") & Format$(ST.wSecond, "00 Uhr")
  End If
End Sub
' Startet den Timer
Public Function EnableTimer(ByVal msInterval As Long)
  If hEvent <> 0 Then Exit Function
  hEvent = SetTimer(0&, 0&, msInterval, AddressOf TimerProc)
End Function
' Beendet den Timer
Public Function DisableTimer()
  If hEvent = 0 Then Exit Function
  KillTimer 0&, hEvent
  hEvent = 0
End Function
' Fügen Sie nachfolgenden Code in eine Form ein
Private Sub Command1_Click()
  EnableTimer 1000
End Sub
Private Sub Command2_Click()
  DisableTimer
End Sub
' Sicherheitshalber das Event Löschen, falls vorhanden
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  DisableTimer
End Sub

Diese Seite wurde bereits 5.249 mal aufgerufen.

nach obenzurück
 
   

Druckansicht Druckansicht Copyright ©2000-2014 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel