Wie speichere ich den Inhalt einer ListBox? VB-Version:  VB5, VB6
	Views:  6.632

Den Inhalt einer ListBox speichern und wieder auslesen geht so:

' Modul:
Public Sub ListeSpeichern(Liste As ListBox, ByVal sFile As String)
  Dim F As Integer
  Dim I As Integer
 
  F = FreeFile
  Open sFile For Output As #F
  With Liste
    For I = 0 To .ListCount - 1
      Print #F, .List(I)
    Next I
  End With
  Close #F
End Sub
 
Public Sub ListeEinlesen(Liste As ListBox, ByVal sFile As String)
  Dim F As Integer
  Dim Eintrag As String
 
  With Liste
    ' sicherheitshalber ListBox leeren
    .Clear
 
    ' nur, wenn Datei "sFile" existiert
    If Dir(sFile) <> "" Then
      F = FreeFile
      Open sFile For Input As #F
      While Not Eof(F)
        Line Input #F, Eintrag
        .AddItem Eintrag
      Wend
      Close #F
    End If
  End With
End Sub

' Form:
' Beim Aufrufen der Form, Liste füllen
Private Sub Form_Load()
  ListeEinlesen List1, App.Path & "\MeineListe.dat"
End Sub
 
' nachfolgenden Code dort einfügen, wo die Liste gespeichert werden soll...
' z.B. beim Beenden der Form
Private Sub Form_Unload()
  ListeSpeichern List1, App.Path & "\MeineListe.dat"
End Sub

Siehe auch folgenden Tipp:  Speichern und Einlesen von Listenfeldinhalten