Datenbankfeld mit "Beschreibung" á la Access (DAO) Man kennt es von MS-Access: zu jedem DB-Feld lässt sich zusätzlich noch eine Beschreibung eingeben. Auch in VB lässt sich das machen!
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  16.049
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 17 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.9 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Sicherlich kennen Sie das von MS-Access: In der Tabellen-Entwurfsansicht lässt sich zu jedem Datenbankfeld eine zusätzliche Beschreibung festlegen. Erstellt man die Tabelle aber nicht mit MS-Access, sondern direkt in VB, fehlt eine solche "Description"-Eigenschaft.

Wie man die Felder einer Datenbanktabelle nachträglich mit einer Description-Eigenschaft ausstattet, das zeigen wir Ihnen heute.

Hierzu muss man lediglich der Properties-Auflistung des Field-Objektes eine neue Eigenschaft namens "Description" spendieren.

Wichtig: Die Properties-Auflistung eines Feldes lässt sich erst erweitern, wenn das Feld bereits in der Tabelle existiert, d.h. beim Erstellen einer neuen Tabelle / eines neues Feldes muss das Feld zunächst der Tabelle hinzugefügt werden, ehe man die neue Description-Eigenschaft hinzufügen kann!

Dim oDB As DAO.Database
Dim oTabDef As New DAO.TableDef
Dim oField As New DAO.Field
Dim oProp As DAO.Property
 
' Datenbank erstellen (Access 2000)
Set oDB = DBEngine.CreateDatabase("test.mdb", dbLangGeneral, dbEncrypt + dbVersion40)
 
' Neue Tabelle
oTabDef.Name = "Artikel"
 
' Neues Feld
With oField
  .Name = "ArtBez"
  .Type = dbText
  .AllowZeroLength = True
  .DefaultValue = ""
End With
 
' Feld der Tabelle hinzufügen
oTabDef.Fields.Append oField
 
' Tabelle der Datenbank hinzufügen
' Tabellendefinition in DB schreiben
oDB.TableDefs.Append oTabDef
 
' Jetzt zusätzliche Field-Properties erstellen
With oDB.TableDefs("Artikel")
  With .Fields("ArtBez")
    Set oProp = .CreateProperty("Description", dbText, _
      "Geben Sie hier die Artikelbezeichnung ein")
    .Properties.Append oProp
  End With
 
  ' ...
End With
oDB.Close

Wenn Sie diese Datenbank nun in MS-Access öffnen, sehen Sie rechts in der Tabellen-Entwurfsansicht neben dem Feld "ArtBez" die Beschreibung Geben Sie hier die Artikelbezeichnung ein.

Möchten Sie den Text ändern, gehen Sie wie folgt vor:

With oDB.TableDefs("Artikel").Fields("ArtBez")
  .Properties("Description") = "Neuer Beschreibungstext"
End With