vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
NEU! sevCoolbar 3.0 - Professionelle Toolbars im modernen Design!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Oberfläche · Sonstiges   |   VB-Versionen: VB5, VB629.06.05
Windows XP Style nachträglich einfügen II

Dieser Tipp verrät, wie man Manifest-Dateien komplett ohne Zusatzsoftware in eine bestehende Anwendung integrieren kann.

Autor:   Martin WalcherBewertung:     [ Jetzt bewerten ]Views:  11.849 
www.martinwalcher.deSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11kein Beispielprojekt 

In einem vorhergehende Tipp wurde gezeigt, wie es mittels des Resource-Hacker möglich ist, nachträglich Manifest-Dateien in eine Anwendung einzufügen und somit XP-Styles zu aktivieren.
Mit diesem Tipp kann man das komplett ohne Zusatzsoftware zu tun!

Als erstes füge man folgenden Code in eine Form (oder Modul, Klasse, etc.) ein:

' bentöigte API-Deklarationen
Private Declare Function BeginUpdateResource Lib "kernel32.dll" _
  Alias "BeginUpdateResourceA" ( _
  ByVal pFileName As String, _
  ByVal bDeleteExistingResources As Long) As Long
 
Private Declare Function UpdateResource Lib "kernel32.dll" _
  Alias "UpdateResourceA" ( _
  ByVal hUpdate As Long, _
  ByVal lpType As Any, _
  ByVal lpName As Any, _
  ByVal wLanguage As Long, _
  ByRef lpData As Any, _
  ByVal cbData As Long) As Long
 
Private Declare Function EndUpdateResource Lib "kernel32.dll" _
  Alias "EndUpdateResourceA" ( _
  ByVal hUpdate As Long, _
  ByVal fDiscard As Long) As Long
 
Private Const manifest As String = _
  "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes""?>" & vbCrLf & _
  "<assembly xmlns=""urn:schemas-microsoft-com:asm.v1"" " & _
  "manifestVersion=""1.0"">" & vbCrLf & _
  "<assemblyIdentity  type=""win32"" processorArchitecture=""*"" " & _
  "version=""6.0.0.0"" name=""Company"" />" & vbCrLf & _
  "<dependency>" & vbCrLf & _
  "<dependentAssembly>" & vbCrLf & _
  "<assemblyIdentity type=""win32"" name=""Microsoft.Windows.Common-Controls"" " & _
  "version=""6.0.0.0"" " & _
  "language=""*"" processorArchitecture=""*"" publicKeyToken=""6595b64144ccf1df""/>" & vbCrLf & _
  "</dependentAssembly>" & vbCrLf & _
  "</dependency>" & vbCrLf & _
  "</assembly>"
Private Function AddXPStyle(ByVal Filename As String) As Boolean
  Dim handle As Long
 
  handle = BeginUpdateResource(Filename, False)
  If handle = 0 Then Exit Function
  UpdateResource handle, 24&, 1&, 0&, ByVal manifest, Len(manifest)
  EndUpdateResource handle, False
 
  AddXPStyle = True
End Function
Private Function DelXPStyle(ByVal Filename As String) As Boolean
  Dim handle As Long
 
  handle = BeginUpdateResource(Filename, False)
  If handle = 0 Then Exit Function
  UpdateResource handle, 24&, 1&, 0&, ByVal 0&, 0&
  EndUpdateResource handle, False
 
  DelXPStyle = True
End Function

Um jetzt XP-Styles in einer EXE zu aktivieren, reicht lediglich der Aufruf:

AddXPStyle "X:\proramm.exe"

Sollen die Themes wieder deaktiviert werden muss folgende Zeile aufgerufen werden:

DelXPStyle "X:\programm.exe"

ACHTUNG! Bei VB-Anwendungen kann es vorkommen, dass die gepatchte Anwendung beim Start ihren Dienst mit der Fehlermeldung "Klasse ist nicht vorhanden" quittiert und sich beendet. In diesem Fall müssen die Controls in der betroffenen Anwendung vorher initiiert werden:

Private Declare Sub InitCommonControls Lib "comctl32.dll" ()
 
Private Sub Form_Initialize()
  Call InitCommonControls
End Sub

Dieser Tipp wurde bereits 11.849 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel