Neuen Benutzer in SQL-Datenbank anlegen Mit dieser Funktion lassen sich neue Benutzer in SQL-Datenbanken erstellen.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  11.897
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 10 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Mit diesem Code lassen sich unter Zuhilfenahme des ADODB-Connection Objekts neue Benutzer in einer Datenbank des MS SQL-Servers (oder MSDE) anlegen.

Option Explicit
 
' Connection-Objekt
Public oConn As ADODB.Connection

' Verbindung zum SQL-Server herstellen
Public Function SQLServerOpenConnection(ByVal sServer As String, _
  ByVal sDatabaseName As String, _
  ByVal sUserName As String, _
  ByVal sPassword As String) As Boolean
 
  Dim sConn As String
 
  On Error GoTo ErrHandler
  If oConn Is Nothing Then
    Set oConn = New ADODB.Connection
 
    ' Connection-String zusammenstellen
    sConn = "Provider=SQLOLEDB.1;" & _
      "Initial Catalog=" & sDatabaseName & ";" & _
      "Data Source=" & sServer & ";" & _
      "Persist Security Info=False;" & _
      "Connect Timeout=45"
 
    With oConn
      .CursorLocation = adUseClient
      .Open sConn, sUserName, sPassword
 
    End With
  End If
  On Error GoTo 0
 
  SQLServerOpenConnection = True
  Exit Function
 
ErrHandler:
  MsgBox "Es ist ein Fehler beim Öffnen der Datenbank aufgetreten." & _
    vbCrLf & CStr(Err.Number) & vbCrLf & Err.Description
End Function

' Neuen Benutzer in der SQL-Datenbank erstellen
Public Function SQLServerAddUser(oConn As ADODB.Connection, _
  ByVal sUserName As String, _
  ByVal sPassword As String, _
  ByVal sDatabaseName As String) As Boolean
 
  On Error GoTo ErrHandler
 
  ' Neuen Benutzer zur Datenbank hinzufügen
  oConn.Execute "USE Master"
  oConn.Execute "EXEC sp_addlogin " & sUserName & "," & _
    sPassword & "," & sDatabaseName
 
  oConn.Execute "USE " & sDatabaseName
  oConn.Execute "EXEC sp_adduser " & sUserName
 
  On Error GoTo 0
  SQLServerAddUser = True
  Exit Function
 
ErrHandler:
  MsgBox "Beim Hinzufügen des Users ist ein Fehler aufgetreten." & vbCrLf & _
    CStr(Err.Number) & " " & Err.Description
End Function

Beispiel für den Aufruf:

' Verbindung zum SQL-Server herstellen
If SQLServerOpenConnection("localhost", "DATENBANKNAME", "sa", "pwd") Then
  ' Neuen Benutzer erstellen
  If SQLServerAddUser(oConn, "Dieter", "geheim", "DATENBANKNAME") Then
    MsgBox "Neuer Benutzer wurde hinzugefügt!"
  End If
  oConn.Close
End If