vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v2.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2015
 
zurück
Rubrik: Controls · ListView   |   VB-Versionen: VB5, VB606.04.06
ListView-Spalten aufsummieren und Summenzeile anzeigen

Hier wird gezeigt, wie man die ListView-Spalten aufsummieren kann und die Werte als Summenzeile im ListView-Control anzeigen lässt.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  8.720 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Summer-Special bei Tools & Components!
Gute Laune Sommer bei Tools & Components
Top Summer-Special - Sparen Sie teilweise über 100,- EUR
Alle sev-Entwicklerkomponenten und Komplettpakete jetzt bis zu 25% reduziert!
zum Beispiel:
  • Developer CD nur 455,- EUR statt 569,- EUR
  • sevDTA 2.0 nur 224,30 EUR statt 299,- EUR
  •  
  • vb@rchiv   Vol.6 nur 18,70 EUR statt 24,95 EUR
  • sevCoolbar 3.0 nur 58,70 EUR statt 69,- EUR
  • - Werbung -Und viele weitere Angebote           Aktionspreise nur für kurze Zeit gültig

    Unser heutiger Tipp zeigt, wie sich die einzelnen Spaltenwerte der ListView-Einträge aufsummieren lassen und die Summen als zusätzliche Summenzeile am unteren Ende der Liste anzeigen lassen. Hierbei werden alle SubItem-Spalten aufsummiert, d.h. die erste Spalte bleibt in unserem Beispiel unberücksichtigt, da Sie der Anzeige der Zeilen-Beschreibung dient. Soll für die erste Spalte ebenfalls eine Smme gebildet und ausgegeben werden, setzen Sie den optionalen Parameter "SumFirstCol" einfach auf True.

    Erstellen Sie ein neues Projekt und platzieren auf die Form ein ListView-Control. Fügen Sie nachfolgenden Code in das Form_Load Ereignis der Form:

    Private Sub Form_Load()
      Dim i As Long
      Dim u As Long
     
      With ListView1
        ' Spalten erstellen
        With .ColumnHeaders
          .Add , , "Bezeichnung", 1500
          ' 5 Summenspalten
          For i = 1 To 5
            .Add , , "Summe " & CStr(i), 1000, 1
          Next i
        End With
     
        ' ListView-Darstellung
        .View = lvwReport
        .FullRowSelect = True
     
        ' ein paar zufällige Summenzeilen einfügen
        Randomize -Timer
        For i = 1 To 10
          With .ListItems.Add(, , "Eintrag " & CStr(i))
            For u = 1 To ListView1.ColumnHeaders.Count - 1
              .SubItems(u) = CStr(Int(100 * Rnd) + 1)
            Next u
          End With
        Next i
      End With
     
      ' Jetzt Summenzeile hinzufügen
      ListView_ShowSumRow ListView1, "Summe"
    End Sub

    Mit obigen Code wird das ListView beim Laden der Form gefüllt. Fehlt jetzt nur noch der Code der Funktion ListView_ShowSumRow:

    Private Sub ListView_ShowSumRow(oListView As Object, ByVal sText As String, _
      Optional ByVal bSumFirstCol As Boolean = False, _
      Optional ByVal bDeleteLastRow As Boolean = False)
     
      ' ListView-Summenzeile hinzufügen
      Dim oItem As ListItem
      Dim nSum() As Long
      Dim i As Long
     
      With oListView
        ' GGf. bereits vorhandene Summenzeile löschen
        If bDeleteLastRow And .ListItems.Count > 0 Then
          .ListItems.Remove .ListItems.Count
        End If
     
        ReDim nSum(.ColumnHeaders.Count - 1)
        For Each oItem In .ListItems
         ' Erste Spalte ebenfalls aufsummieren?
          If bSumFirstCol Then
            nSum(0) = nSum(0) + Val(oItem.Text)
     
          End If
     
          ' Summen aller SubItem-Spalten bilden
          For i = 1 To .ColumnHeaders.Count - 1
            nSum(i) = nSum(i) + Val(oItem.SubItems(i))
          Next i
        Next
     
        ' Summenzeile am Ende der Liste hinzufügen
        With .ListItems.Add(, , IIf(bSumFirstCol, CStr(nSum(0)), sText))
          For i = 1 To ListView1.ColumnHeaders.Count - 1
            .SubItems(i) = CStr(nSum(i))
          Next i
        End With
      End With
    End Sub

    Hinweis:
    Werden die Werte im ListView verändert und soll die Summenzeile daraufhin neu ermittelt werden, rufen Sie die ListView_ShowSumRow-Funktion wie folgt auf:

    ' Summenzeile neu ermitteln und anzeigen
    ' Der optionale True-Parameter gibt an, dass die bestehende 
    ' Summenzeile vorher gelöscht werden soll, da diese sonst 
    ' mit in die neue Berechnung der Summen einfliest
    ListView_ShowSumRow ListView1, "Summe", , True

    Dieser Tipp wurde bereits 8.720 mal aufgerufen.

    Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

    Über diesen Tipp im Forum diskutieren
    Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

    Neue Diskussion eröffnen

    nach obenzurück


    Anzeige

    Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
    (einschl. Beispielprojekt!)

    Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
    - nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
    - Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
    Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
     
       

    Druckansicht Druckansicht Copyright ©2000-2015 vb@rchiv Dieter Otter
    Alle Rechte vorbehalten.
    Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

    Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel