vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Erstellen von dynamischen Kontextmen?s - wann immer Sie sie brauchen!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Variablen/Strings · String-Operationen   |   VB-Versionen: VB630.08.06
TextWrap - autom. Textumbruch nach x Zeichen

Mit dieser Funktion lassen sich lange Texte auf mehrere Zeilen umbrechen, wobei die maximale Zeilenlänge angegeben werden kann.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  14.387 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Heute möchten wir Ihnen eine Funktion vorstellen, mit der sich lange Texte (mit oder ohne Zeilenumbrüche) auf mehrere Zeilen verteilen lassen, wobei die maximale Länge der Zeilen als Parameter angegeben wird.

' autom. Textumbruch nach x-Zeichen
Public Function TextWrap(ByVal sText As String, _
  Optional ByVal nMaxLen As Long = 72) As String
 
  Dim nStart As Long
  Dim nPos As Long
  Dim sLine As String
 
  ' nach harten Zeilenumbrüchen suchen
  nStart = 1
  Do
    nPos = InStr(nStart, sText, vbNewLine)
    If nPos > 0 Then
      ' jetzt Zeile umbrechen
      sLine = Mid$(sText, nStart, nPos - nStart)
      TextWrap = TextWrap & LineWrap(sLine, nMaxLen) & vbNewLine
      nStart = nPos + Len(vbNewLine)
    End If
  Loop Until nPos = 0
 
  If nStart <= Len(sText) Then
    ' Letzte Zeile muss ggf. noch umgebrochen werden
    TextWrap = TextWrap & LineWrap(Mid$(sText, nStart), nMaxLen)
  End If
End Function
Private Function LineWrap(ByVal sLine As String, _
  ByVal nMaxLen As Long) As String
 
  Dim nPos As Long
 
  ' Solange die Zeile länger als die gewünschte Länge ist
  Do While Len(sLine) > nMaxLen
    ' nach Leerzeichen suchen
    nPos = InStrRev(sLine, " ", nMaxLen)
    If nPos = 0 Then nPos = nMaxLen
 
    ' Zeile an der gefundenen Stelle umbrechen
    LineWrap = LineWrap & RTrim$(Left$(sLine, nPos)) & vbNewLine
    sLine = LTrim$(Mid$(sLine, nPos + 1))
  Loop
  LineWrap = LineWrap & sLine
End Function

Beispiel für den Aufruf:

Dim sText As String
 
sText = "Dies ist ein etwas längerer Text, " & _
  "der autom. nach 25 Zeichen umgebrochen werden soll." & vbCrLf & _
  "Und das ist dann die nächste Zeile, die umgebrochen wird."
 
' autom. Zeilenumbruch nach 30 Zeichen
MsgBox TextWrap(sText, 30)

Dieser Tipp wurde bereits 14.387 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel