vb@rchiv · Tipps & Tricks · Eigenen Bildschirmschoner programmieren

Rubrik: System/Windows · Desktop/Bildschirm/Display | VB-Versionen: VB4, VB5, VB6

20.03.07

Eigenen Bildschirmschoner programmieren Dieser Tipp zeigt, wie man schnell und einfach einen eigenen Bildschirmschoner mit VB programmieren kann.
Autor: Hawker	Bewertung:	Views: 13.526
ohne Homepage	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Dieser Tipp zeigt, wie man schnell und einfach einen eigenen Bildschirmschoner mit VB programmieren kann.

Die Eigenschaften von Form1 müssen wie folgt verändert werden:

Caption = ""
ControlBox = False
MaxButton = False
MinButton = False
WindowState = 2 (maximized)

Nun zum Quellcode:

Option Explicit
 
' benötigte API-Deklaration zum verstecken des Mauszeigers
Private Declare Function ShowCursor Lib "user32" _
  (ByVal bShow As Long) As Long

' Windows startet den Screensaver normalerweise mehrmals hintereinander.
' Um dem entgegenzuwirken, wird bei jedem Start geprüft, ob das Programm
' bereits läuft und gegebenenfalls beendet.
Private Sub Form_Load()
  If App.PrevInstance Then
    End
  End If
 
  ' Mauszeiger verstecken
  ShowCursor 0 
End Sub

' Bei einer Mausbewegung oder einer Tastatureingabe soll 
' das Programm beendet werden und der Mauszeiger wieder 
' sichtbar werden
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
  AppClose
End Sub
 
Private Sub Form_KeyPress(KeyAscii As Integer)
  AppClose
End Sub
 
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, _
  x As Single, y As Single)
 
  AppClose
End Sub

' Wenn das Programm gestartet wird, wird automatisch dreimal das
' MouseMove-Ereignis ausgelöst; also müssen die ersten drei
' MouseMove-Ereignisse ignoriert werden.
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, _
  x As Single, y As Single)
 
  Static count As Integer
 
  If count > 3 Then
    AppClose
  Else
    count = count + 1
  End If
End Sub

' Mauszeiger einschalten und Anwendung beenden
Private Sub AppClose()
  ShowCursor 1
  Unload Me
End Sub

Nun zum wichtigsten: dem Erstellen des Bildschirmschoners. Um keine EXE, sondern eine .scr-Datei zu bekommen, wird beim Erstellen des Projekts einfach ein ".scr" an den Dateinamen angehängt (also z.B. "Screensaver.scr").