vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Schützen Sie Ihre Software vor Software-Piraterie - mit sevLock 1.0 DLL!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Variablen/Strings · Algorithmen/Mathematik   |   VB-Versionen: VB5, VB608.04.08
Base64-Codierung eines Strings

Mit dieser Funktion lässt sich ein beliebiger Datenstrom (String) in das Base64-Format codieren.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  16.209 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Base64 beschreibt ein Verfahren zur Kodierung von 8-Bit -Binärdaten in eine Zeichenfolge, die nur aus 63 Codepage-unabhängigen Zeichen besteht. Das Base64-Verfahren findet man vor allem im Internet beim Versenden von EMail-Anlagen, die i.a.R. base64-codiert verschickt werden und somit plattformunabhängig wieder decodiert werden können.

Zur Codierung werden immer 3 Bytes (24 Bit) des Original-Datenstroms zu vier 6-Bit-Blöcke zusammengefasst, wobei jeder dieser 6-Bit Blöcke eine Zahl zwischen 0 und 63 bildet. Der Ausgabestrom ist daher um 33% größer als das Original.

Falls die Länge des Originalstrings nicht durch 3 teilbar ist, wird der zu codierende Text am Ende mit = Zeichen aufgefüllt, so dass der Ausgabestring immer durch 4 teilbar ist (ohne Rest).

Nachfolgende Funktion codiert den übergebenen String in das Base64-Format und gibt dieses als String zurück.

' String nach Base64 codieren
Public Function Encode64(ByVal sInput As String) As String
  Dim i As Long
  Dim sBase64 As String
  Dim nByte As Long
  Dim nChar As Long
  Dim nOldChar As Long
  Dim sChar As String
  Dim nLen As Long
  Dim sOutput As String
  Dim nPos As Long
 
  ' Zulässige Zeichen (base64)
  sBase64 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ" & _
    "abcdefghijklmnopqrstuvwxyz" & _
    "0123456789+/"
 
  nLen = Len(sInput)
  If nLen > 0 Then
    ' aus je 3 Bytes werden 4 Base64-codierte Bytes
    sOutput = Space$(nLen / 3 * 4 + 2)
 
    ' String durchlaufen
    nPos = 1
    For i = 1 To nLen
      nByte = nByte + 1
 
      ' Ascii-Zeichen des Originalstrings
      nChar = Asc(Mid$(sInput, i, 1))
      Select Case nByte
        Case 1
          sChar = Mid$(sBase64, 1 + ((Int(nChar / 4) And &H3F)), 1)
          Mid$(sOutput, nPos, 1) = sChar
 
        Case 2
          sChar = Mid$(sBase64, 1 + ((((nOldChar * 16) And &H30) Or _
           ((Int(nChar / 16) And &HF)))), 1)
          Mid$(sOutput, nPos, 1) = sChar
 
        Case 3
          sChar = Mid$(sBase64, 1 + ((((nOldChar * 4) And &H3C) Or _
            ((Int(nChar / 64) And &H3)))), 1) & _
            Mid$(sBase64, 1 + ((nChar And &H3F)), 1)
          Mid$(sOutput, nPos, 2) = sChar
          nPos = nPos + 1
          nByte = 0
 
      End Select
      nPos = nPos + 1
      nOldChar = nChar
    Next i
 
    ' ggf. noch mit = auffüllen
    Select Case nByte
      Case 1
        sChar = Mid$(sBase64, 1 + (((nOldChar * 16) And &H30)), 1)
        Mid$(sOutput, nPos, 3) = sChar & "=="
      Case 2
        sChar = Mid$(sBase64, 1 + (((nOldChar * 4) And &H3C)), 1)
        Mid$(sOutput, nPos, 2) = sChar & "="
    End Select
  End If
 
  Encode64 = RTrim$(sOutput)
End Function

Dieser Tipp wurde bereits 16.209 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel