Seriennummer Generator .Net VB.Net Klassenmodul zum Erzeugen einer zufälligen Seriennummer
Autor:   Roland Wutzke	Bewertung:	Views:  17.318
www.vb-power.net	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Im Forum wird immer mal wieder gefragt, wie man eine eindeutige Seriennummer erzeugen kann. Oft wird dazu die Random Methode benutzt, um eine Seriennummer zu erzeugen.

In dem nachfolgenden VB.Net Klassenmodul wird darauf verzichtet und stattdessen die NewGuid-Methode aus der Guid Klasse benutzt. Die Rückgabe der Seriennummer erfolgt dabei über die überschriebene ToString Methode. Im Konstruktor der Klasse kann zusätzlich die Anzahl der Blöcke und die Länge je Block festgelegt werden. Als Default wird eine Seriennummer bestehend aus zwei Blöcken mit je sechs Zeichen zurückgegeben. Als Trenner zwischen den Blöcken wird ein Bindestrich verwendet.

Imports System.Text
 
''' <summary>
''' SerialNumber Generator Class
''' </summary>
''' <remarks>
''' Die Klasse erzeugt eine zufällige Seriennummer. Die Rückgabe erfolgt
''' über die .ToString Methode. Im Konstruktor wird festgelegt, wieviele
''' Blöcke und mit welcher Blocklänge die Seriennummer erzeugt wird.
''' 
''' September 2008 - VB-Power.net
''' </remarks>
Public Class SerialNumber

  ' Member Variablen
  Private m_BlockLength As Int16 = 6
  Private m_BlockCount As Int16 = 2
  Private m_Delimiter As String = "-"

  ''' <summary>
  ''' Initialisiert die Klasse
  ''' </summary>
  Public Sub New()
  End Sub

  ''' <summary>
  ''' Initialisiert die Klasse
  ''' </summary>
  ''' <param name="BlockLength">Legt die Länge eines Blocks fest.</param>
  ''' <param name="BlockCount">Legt die Anzahl Blöcke in der Seriennummer fest.</param>
  Public Sub New(ByVal BlockLength As Int16, ByVal BlockCount As Int16)
    m_BlockLength = BlockLength
    m_BlockCount = BlockCount
  End Sub

  ''' <summary>
  ''' Initialisiert die Klasse
  ''' </summary>
  ''' <param name="BlockLength">Legt die Länge eines Blocks fest.</param>
  ''' <param name="BlockCount">Legt die Anzahl Blöcke in der Seriennummer fest.</param>
  ''' <param name="Delimiter">Legt den Trenner zwischen den Blöcken fest.</param>
  Public Sub New(ByVal BlockLength As Int16, ByVal BlockCount As Int16, _
    ByVal Delimiter As String)
 
    m_BlockLength = BlockLength
    m_BlockCount = BlockCount
    m_Delimiter = Delimiter
  End Sub

  Private Function Generate(ByVal BlockLength As Int16, _
     ByVal BlockCount As Int16, ByVal Delimiter As String) As String
 
    Dim si As New StringBuilder
    Dim sb As New StringBuilder
    For n As Int16 = 0 To BlockCount - 1
      Try
        si.Append(Guid.NewGuid.ToString().Replace("-", "").ToUpper)
        sb.Append(si.ToString.Substring(n * BlockLength, BlockLength) & Delimiter)
      Catch ex As Exception
        Throw New Exception("Fehler beim Erstellen der Seriennummer.")
      End Try
    Next
 
    Return sb.ToString.Substring(0, sb.Length - Delimiter.Length)
  End Function

  ''' <summary>
  ''' Gibt die erzeugte Seriennummer zurück.
  ''' </summary>
  Public Overrides Function ToString() As String
    Return Me.Generate(m_BlockLength, m_BlockCount, m_Delimiter)
  End Function

End Class

Aufrufbeispiel:

' Seriennumer mit 4 Blöcken á 6 Zeichen generieren
Dim sNumber As String = New SerialNumber(6, 4).ToString

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.