vb@rchiv · Tipps & Tricks · Anzahl Dateien und Größe im Windows Papierkorb ermitteln

Rubrik: Dateisystem · Dateien allgemein | VB-Versionen: VB6

15.05.09

Anzahl Dateien und Größe im Windows Papierkorb ermitteln Dieser Tipp zeigt, wie sich die Anzahl Dateien und deren Gesamtgröße im Windows-Papierkorb ermitteln lassen - entweder systemweit oder optional auch nur für ein bestimmtes Laufwerk.
Autor: Dieter Otter	Bewertung:	Views: 9.832
www.tools4vb.de	System: WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Dieser Tipp zeigt, wie sich die Anzahl Dateien und deren Gesamtgröße im Windows-Papierkorb ermitteln lassen - entweder systemweit oder optional auch nur für ein bestimmtes Laufwerk.

' benötigte API-Deklarationen
Private Declare Function SHQueryRecycleBin Lib "shell32.dll" _
  Alias "SHQueryRecycleBinA" ( _
  ByVal pszRootPath As String, _
  pSHQueryRBInfo As SHQUERYRBINFO) As Long
 
Private Type SHQUERYRBINFO
  cbSize As Long
  i64Size As Currency
  i64NumItems As Currency
End Type
 
Private Type RBINFO
  NumItems As Currency
  TotalSize As Currency
End Type

' Ermittelt die Anzahl Dateien und deren Größe im Windows-Papierkorb
' Optional kann auch ein Laufwerk angegeben werden, bspw. C:
Private Function RecycleBinInfo(Optional ByVal sPath As String = "") As RBINFO
  Dim RB As SHQUERYRBINFO
 
  ' API-Funktion aufrufen
  RB.cbSize = Len(RB)
  Call SHQueryRecycleBin(sPath, RB)
 
  ' Rückgabewerte
  With RecycleBinInfo
    .NumItems = RB.i64NumItems * 10000
    .TotalSize = RB.i64Size * 10000
  End With
End Function

Aufrufbeispiel:

' Anzahl Dateien im Windows Papierkorb systemweit
With RecycleBinInfo()
  Debug.Print "Anzahl Dateien: " & .NumItems
  Debug.Print "Gesamtgröße (Bytes): " & .TotalSize
End With

' Anzahl Dateien im Windows Papierkorb auf Laufwerk C:
With RecycleBinInfo("C:")
  Debug.Print "Anzahl Dateien: " & .NumItems
  Debug.Print "Gesamtgröße (Bytes): " & .TotalSize
End With