vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Controls · TextBox & RichTextBox   |   VB-Versionen: VB2005, VB200827.07.09
MultiLine-TextBox zeilenweise in Liste übertragen

Übertragen der einzelnen Zeilen einer MultiLine-TextBox in eine ListBox unter Berücksichtigung von festen als auch optional von weichen Zeilenumbrüchen.

Autor:   Dieter OtterBewertung:  Views:  12.560 
www.tools4vb.deSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Das nachfolgende Beispiel zeigt, wie sich die einzelnen Zeilen einer MultiLine-TextBox zeilenweise in eine ListBox übertragen lassen. Die überladene Prozedur "TextBox2ListBox" kann hierbei so verwendet werden, dass entweder nur feste Zeilenumbrüche berücksichtigt werden oder optional auch die weichen Zeilenumbrüche. Es soll in diesem Fall also keine Rolle spielen, ob die Zeilen automatisch beim Erreichen des rechtes Randes umgebrochen wurde oder die "Enter"-Taste für den Umbruch verwendet wurde.

Wird für den Parameter "OnlyHardCR" der Wert "False" angegeben, werden die Zeilen exakt so, wie sie auch in der TextBox angezeigt werden, in eine ListBox übertragen.

' API-Deklarationen
Private Declare Auto Function SendMessage Lib "user32" ( _
  ByVal hwnd As IntPtr, _
  ByVal wMsg As Integer, _
  ByVal wParam As Integer, _
  ByVal lParam As Integer) As Long
 
Private Const EM_FMTLINES = &HC8
''' <summary>
''' Überträgt die Zeilen einer MultiLine-TextBox in eine ListBox
''' </summary>
''' <param name="TextBox">MultiLine-TextBox</param>
''' <param name="ListBox">ListBox-Control</param>
Public Sub TextBox2ListBox(ByVal TextBox As TextBox, ByVal ListBox As ListBox)
  TextBox2ListBox(TextBox, ListBox, True)
End Sub
''' <summary>
''' Überträgt die Zeilen einer MultiLine-TextBox in eine ListBox
''' </summary>
''' <param name="TextBox">MultiLine-TextBox</param>
''' <param name="ListBox">ListBox-Control</param>
''' <param name="OnlyHardCR">True, wenn nur feste Zeilenumbrüche 
''' berücksichtigt werden sollen.
''' False, wenn sowohl feste, als auch weiche (automatische)
''' Zeilenumbrüche berüskcitigt werden sollen.</param>
Public Sub TextBox2ListBox(ByVal TextBox As TextBox, ByVal ListBox As ListBox, _
  ByVal OnlyHardCR As Boolean)
 
  ' ListBox löschen
  ListBox.Items.Clear()
 
  If OnlyHardCR Then
    ' nur feste Zeilenumbrüche berücksichtigen
    ListBox.Items.AddRange(TextBox.Lines)
  Else
    ' sowohl feste, als auch weiche (automatische) 
    ' Zeilenumbrüche(berücksichtigen)
 
    ' autom. Umbrüche durch CR CR LF ersetzen
    SendMessage(TextBox.Handle, EM_FMTLINES, 1, 0)
 
    ' Text temporär zwischenspeichern
    Dim sText As String = TextBox.Text
 
    ' eingefügte Umbrüche wieder rückgängig machen
    SendMessage(TextBox.Handle, EM_FMTLINES, 0, 0)
 
    ' Inhalt als String-Array zurückgeben
    sText = sText.Replace(vbCr, "")
    ListBox.Items.AddRange(sText.Split(vbLf))
  End If
End Sub



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.