CD-Laufwerk öffnen und schließen Zwei Funktionen, mit denen sich die Schublade des Standard CD-Laufwerk oder auch ein ganz bestimmtes CD-Laufwerk öffnen und wieder schließen lässt.
Autor:   Dieter Otter	Bewertung:	Views:  12.235
www.tools4vb.de	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Heute stellen wir Ihnen jeweils zwei überladene Prozeduren vor, mit denen sich das CD-Laufwerk öffnen und wieder schließen lässt. Wird die jeweilige Prozedur ohne Parameter aufgerufen, wird das Standard CD-Laufwerk geöffnet bzw. geschlossen. Alternativ kann man aber auch durch Angabe des Laufwerksbuchstabens ein ganz bestimmtes CD-Laufwerk ansprechen.

' API-Deklaration
Private Declare Auto Function mciSendString Lib "winmm.dll" ( _
  ByVal lpstrCommand As String, _
  ByVal lpstrReturnString As String, _
  ByVal uReturnLength As Integer, _
  ByVal hwndCallback As Integer) As Integer

''' <summary>
''' Standard CD-Laufwerk öffnen
''' </summary>
Public Sub DriveOpen()
  ' CD-Laufwerk öffnen
  mciSendString("set cdaudio door open", 0, 0, 0)
End Sub

''' <summary>
''' Bestimmtes CD-Laufwerk öffnen
''' </summary>
''' <param name="DriveName">CD-Laufwerksbuchstabe</param>
Public Sub DriveOpen(ByVal DriveName As String)
  ' ggf. Doppelpunkt anfügen
  If DriveName.Length = 1 Then DriveName = DriveName & ":"
 
  ' CD-Laufwerk öffnen
  Dim Buffer As String = Strings.Space(255)
 
  mciSendString("Open " & DriveName & " Type cdaudio Alias cd", Buffer, 255, 0)
  mciSendString("set cd door open", 0, 0, 0)
  mciSendString("close cd", 0, 0, 0)
End Sub

''' <summary>
''' Standard CD-Laufwerk schließen
''' </summary>
Public Sub DriveClose()
  ' CD-Laufwerk schließen
  mciSendString("set cdaudio door closed", 0, 0, 0)
End Sub

''' <summary>
''' Bestimmtes CD-Laufwerk schließen
''' </summary>
''' <param name="DriveName">CD-Laufwerksbuchstabe</param>
Public Sub DriveClose(ByVal DriveName As String)
  ' ggf. Doppelpunkt anfügen
  If DriveName.Length = 1 Then DriveName = DriveName & ":"
 
  ' CD-Laufwerk schließen
  Dim Buffer As String = Strings.Space(255)
 
  mciSendString("Open " & DriveName & " Type cdaudio Alias cd", Buffer, 255, 0)
  mciSendString("set cd door closed", 0, 0, 0)
  mciSendString("close cd", 0, 0, 0)
End Sub

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.