vb@rchiv · Tipps & Tricks · Alle verfügbaren Schriftarten in Word auflisten

Rubrik: Grafik und Font · Font & Text | VB-Versionen: VB6

05.04.10

Alle verfügbaren Schriftarten in Word auflisten Funktion, um alle verfügbaren Schriftarten mit einem Beispieltext in Word aufzulisten.
Autor: Dennis Hemken	Bewertung:	Views: 13.517
gadgets.hemken.org	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Die mühselige Suche nach einer schönen Schriftart für "was auch immer" ist vorbei.

Sie suchen eine passende Schriftart für die Einladungskarte der alljährlichen HalloweenFeier, oder Ihres nächsten runden Geburtstags, oder Sie wollen einfach alle verfügbaren Schriftarten, die ihr Windows bietet, auflisten? Dann ist diese Funktion genau das richtige für Sie.

Public Sub ListAllFontsInWord(ByVal strExampleText As String)
  Dim objWord As Object
  Dim lngCount As Long
  Dim strFontName As String
 
  ' Word-Objekt erzeugen
  Set objWord = CreateObject("Word.Application")
 
  ' Word anzeigen
  objWord.Visible = True
 
  ' Word-Dokument hinzufügen
  objWord.Documents.Add
 
  ' for next über alle Schriftarten
  For lngCount = 0 To objWord.FontNames.Count - 1
    ' Name der Schriftart auslesen
    strFontName = objWord.FontNames(lngCount + 1)
 
    With objWord.Selection
      ' Standardformat für die lesbare Ausgabe der darunter
      ' ausgegebenen Schriftart setzen
      .Font.Name = "Arial"
      .Font.Bold = True
      .Font.Size = 14
 
      ' Name der Schriftart ausgeben in dem lesbaren
      ' Standardformat ausgeben
      .TypeText lngCount + 1 & ". " & strFontName & Chr(11)
 
      ' und eine Zeile runter
      .MoveDown 4, 1, 0
 
      ' Format für den Bespieltext setzen
      .Font.Name = strFontName
      .Font.Bold = False
      .Font.Size = 12
 
      ' den Beispieltext ausgeben
      .TypeText strExampleText & Chr(11)
 
      ' Alternative zum Beispieltext sind alle gebräuchlichen
      ' Buchstaben in Groß- und Kleinschreibung,
      ' sowie Zahlen und einige Sonderzeichen
      '.TypeText "AaBbCcDdEeFfGgHhIiJjKkLlMmNnOoPpQqRr" & _
      '   "SsTtUuVvWwXxYyZzÄäÖöÜüß" & Chr(11)
      '.TypeText "0123456789?$%&()[]*_-=+/<>"
 
      ' Paragraph einfügen and wieder runter
      .InsertParagraphAfter
      .InsertParagraphAfter
      .MoveDown 4, 1, 0
    End With
  Next
End Sub

Beispielaufruf:

strExampleText = "Bei vb@rchiv findet man super Tipps und Tricks"
Call ListAllFontsInWord(strExampleText)

strExampleText = "Happy Birthday, Onkelchen"
Call ListAllFontsInWord(strExampleText)