vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Variablen/Strings · String-Operationen   |   VB-Versionen: VB625.01.12
StrContains für VB6 mit erweiterten Suchparametern

Eine Funktion, die prüft, ob in einem String eine bestimmte Zeichenkette enthalten ist.

Autor:   Dieter OtterBewertung:  Views:  8.458 
www.tools4vb.deSystem:  Win9x, WinNT, WinXP, Win7, Win8, Win10, Win11kein Beispielprojekt 

Um zu prüfen, ob in einem String eine bestimmte Zeichenkette vorhanden ist, verwendet man i.a.R. die VB-Funktion InStr. Diese Funktion gibt die Position des ersten Vorkommens der Zeichenkette innerhalb des übergebenen Strings zturück.

Jetzt ergibt sich oftmals das "Problem", dass man den String nicht nur auf eine Zeichenkette hin prüfen will, sondern auf eine ganze Reihe Zeichenketten, d.h. es soll geprüft werden, ob in dem String die Zeichenkette A oder B oder C usw. enthalten ist. Hierfür müsste man die InStr-Funktion x-mal aufrufen und jeweils mit OR verknüpfen:

If InStr("String", "ab") > 0 Or InStr("String", "cd") > 0 Or InStr("String", "ef") > 0 Then
...
Einfacher wäre es, wenn man hierfür nur eine einzige Funktion aufrufen könnte und die verschiedenen Zeichenketten einfach als Parameter übergeben würde.

Und genau das erledigt nachfolgende Funktion:

' Prüft, ob im String eine der als Parameter-Array 
' übergebenen Zeichenketten vorhanden ist
Public Function StrContains(ByVal sData As String, _
  ByVal CompareMethod As VbCompareMethod, _
  ParamArray vArg() As Variant) As Boolean
 
  Dim i As Long
  Dim bFound As Boolean
 
  bFound = False
  If Len(sData) > 0 Then
    For i = 0 To UBound(vArg)
      If InStr(1, sData, vArg(i), CompareMethod) > 0 Then
        bFound = True
        Exit For
      End If
    Next i
  End If
 
  StrContains = bFound
End Function

Die Vergleichsmethode für den String-Vergleich lässt sich über den CompareMethod-Parameter festlegen (analog zur InStr-Funktion).

Die einzelnen Zeichenketten übergibt man der Funktion einfach hintereinander. Die Anzahl spielt keine Rolle, da der Parameter innerhalb der Funktionseklaration als ParamArray definiert ist.

Anwendungsbeispiel:

Dim sData As String
sData = "Zuständig für die Aufgabe: D.Otter"
 
' Prüft, ob in sData die Zeichenfolge "zuständig", 
' "zustaendig" oder "verantwortlich" enhalten ist
If StrContains(sData, vbTextCompare, "zuständig", "zustaendig", "verantwortlich") Then
 ...
End If



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.