Netzlaufwerk verbinden und trennen Zwei Möglichkeiten, Netzlaufwerke zu verbinden und zu trennen - per Windows-Dialog oder direkt per Code.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  47.934
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 38 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.3 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Das Windows-API stellt uns verschiedene Funktionen zur Verfügung, um Netzlaufwerke zu verbinden und zu trennen. Die wohl gängigste (und von vielen anderen Anwendungen ebenfalls genutzte) Methode, ist das Anzeigen des Standard Windows-Dialogs zum Verbinden / Trennen von Netzlaufwerken.

Wenn auch Sie den Windows-Dialog in Ihrer Anwendung verwernden möchten, benötigen Sie nachfolgende API-Funktionen undVB-Code:

Netzlaufwerk verbinden/trennen per Windows-Dialog

' Netzlaufwerk verbinden/trennen (per Dialog)
Private Declare Function WNetConnectionDialog Lib "mpr.dll" ( _
  ByVal hWnd As Long, _
  ByVal dwType As Long) As Long
 
Private Declare Function WNetDisconnectDialog Lib "mpr.dll" ( _
  ByVal hWnd As Long, _
  ByVal dwType As Long) As Long
 
Private Const RESOURCETYPE_DISK = &H1
Private Const WN_SUCCESS = 0

' Netzlaufwerk verbinden (per Dialog)
Dim lResult As Long
 
lResult = WNetConnectionDialog(Me.hWnd, _
  RESOURCETYPE_DISK)
 
If lResult <> WN_SUCCESS Then
  MsgBox "Fehler oder Benutzerabbruch!"
End If

' Netzlaufwerk trennen (per Dialog)
Dim lResult As Long
 
lResult = WNetDisconnectDialog(Me.hWnd, _
  RESOURCETYPE_DISK)
 
If lResult <> WN_SUCCESS Then
  MsgBox "Fehler oder Benutzerabbruch!"
End If

Es gibt aber noch eine andere Möglichkeit, ein Netzlaufwerk zu verbinden bzw. auch wieder zu trennen. Das Windows-API hält hier noch zwei weitere Funktionen bereit - WNetAddConnection und WNetCancelConnection.

Mit diesen beiden Funktionen lässt sich eine Netzlaufwerk-Verbindung "im Silent-Mode" realisieren, d.h. ein Netzlaufwerk kann direkt ohne zusätzlichen Dialog mit einem Ordner eines anderen Rechners verbunden werden - ebenso wie die Trennung einer bestehenden Netzlaufwerk-Verbindung.

Hierzu werden nachfolgende API-Funktionen benötigt:

' Netzlaufwerk verbinden/trenne (ohne Windows-Dialog)
Private Declare Function WNetAddConnection Lib "mpr.dll" _
  Alias "WNetAddConnectionA" ( _
  ByVal lpszNetPath As String, _
  ByVal lpszPassword As String, _
  ByVal lpszLocalName As String) As Long
 
Private Declare Function WNetCancelConnection Lib "mpr.dll" _
  Alias "WNetCancelConnectionA" ( _
  ByVal lpszName As String, _
  ByVal bForce As Long) As Long
 
' Fehler-/Rückgabe-Konstanten
Private Const WN_SUCCESS = 0
Private Const WN_NET_ERROR = 2
Private Const WN_BAD_PASSWORD = 6

' Netzlaufwerk verbinden
Public Function Drive_Connect(ByVal LocalDrive As String, _
  ByVal NetworkPath As String, _
  Optional ByVal ShowError As Boolean = False) As Boolean
 
  Dim lResult As Long
 
  lResult = WNetAddConnection(NetworkPath, _
    vbNullString, LocalDrive)
 
  If ShowError And lResult <> WN_SUCCESS Then
    If lResult = WN_NET_ERROR Then
      MsgBox "Netzwerkfehler!"
    ElseIf lResult = WN_BAD_PASSWORD Then
      MsgBox "Ungültiges Passwort!"
    Else
      MsgBox "Unbekannter Fehler"
    End If
  End If
 
  Drive_Connect = (lResult = WN_SUCCESS)
End Function

' Netzlaufwerk trennen
Private Function Drive_Disconnect( _
  ByVal LocalDrive As String, _
  Optional ByVal ShowError As Boolean = False) As Boolean
 
  Dim lResult As Long
 
  lResult = WNetCancelConnection(LocalDrive, True)
 
  If ShowError And lResult <> WN_SUCCESS Then
    If lResult = WN_NET_ERROR Then
      MsgBox "Netzwerkfehler!"
    ElseIf lResult = WN_BAD_PASSWORD Then
      MsgBox "Ungültiges Passwort!"
    Else
      MsgBox "Unbekannter Fehler"
    End If
  End If
 
  Drive_Disconnect = (lResult = WN_SUCCESS)
End Function

Beispiel:

' Netzlaufwerk verbinden
' K: (lokal) mit \\SERVER\C
' (evtl. Fehler anzeigen)
Drive_Connect "K:", "\\SERVER\C", True
 
' Netzlaufwerk trennen (K:)
' (evtl. Fehler unterdrücken)
Drive_Disconnect "K:", False

Erweiterung:
Wenn Sie den Windows-Verbinden-Dialog benutzen, steht sofort eine Liste aller auf dem lokalen Rechner NICHT belegter Laufwerksbuchstaben zur Auswahl. Somit kann nicht aus Versehen ein bereits vorhandener Laufwerksbuchstaben für eine Netzlaufwerk-Verbindung benutzt werden.

Und genau eine solche Funktion können Sie ebenfalls in Ihrer Anwendung benutzen. Die nachfolgende Funktion gibt den ersten freien Laufwerksbuchstaben zurück, welcher für eine Netzlaufwerk-Verbindung genutzt werden kann.

' benötigte API-Deklaration
Private Declare Function GetLogicalDriveStrings Lib "kernel32" _
  Alias "GetLogicalDriveStringsA" ( _
  ByVal nBufferLength As Long, _
  ByVal lpBuffer As String) As Long

' Ersten freien Laufwerksbuchstaben ermitteln
Public Function GetFreeLocalDrive() As String
  Dim sBuffer As String * 255
  Dim sDrives As String
  Dim lResult As Long
  Dim sDrive As String
  Dim sPos As Integer
  Dim LogicalDrive(25) As String
  Dim I As Integer
 
  ' Laufwerksbuchstaben A: - Z:
  For I = 0 To 25
    LogicalDrive(I) = Chr$(65 + I) + ":"
  Next I
 
  ' zunächst alle belegten Laufwerksbuchstaben ermitteln
  lResult = GetLogicalDriveStrings(Len(sBuffer), sBuffer)
  sDrives = Left$(sBuffer, lResult)
 
  While Len(sDrives) > 0
    sPos = InStr(sDrives, Chr$(0))
    sDrive = Left$(sDrives, sPos - 1)
    sDrives = Mid$(sDrives, sPos + 1)
 
    ' Aus dem Array "streichen"
    LogicalDrive(Asc(Left$(sDrive, 1)) - 65) = ""
  Wend
 
  For I = 3 To 25
    If LogicalDrive(I) <> "" Then
      ' erster freier Laufwerksbuchstabe
      GetFreeLocalDrive = LogicalDrive(I)
      Exit For
    End If
  Next I
End Function

Beispiel:

' Netzlaufwerk verbinden mit \\SERVER\C
' (evtl. Fehler anzeigen)
Dim LocalDrive As String
 
LocalDrive = GetFreeLocalDrive()
Drive_Connect LocalDrive, "\\SERVER\C", True