Icons und Text im Menü Ein Beispiel das zeigt, wie sich VB-Menüeinträge mit Icon und Text darstellen lassen.
Autor:   Manfred P. Bauer	Bewertung:     [ Jetzt bewerten ]	Views:  22.878
home.pages.at/mpbauer1	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 23 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Bekanntlich kann in Visual Basic ein Menüeintrag entweder aus Text oder aus einem Bild bestehen. Scheinbar ist es jedoch nicht möglich, beides zu kombinieren. Mit dem folgenden Tipp klappt es aber doch. Wir nutzen dazu die Möglichkeit, der Checked-Eigenschaft eines Menüeintrags ein Bild zuweisen zu können.

Legen Sie auf einer Form ein Menü mit allen gewünschten Text-Einträgen an. Für die dazu gehörigen Bilder plazieren Sie Picture-Boxes mit Ihren Icons irgendwo auf der Form und setzen deren Visible-Eigenschaft auf "False". Wenn Sie für "Checked=True" und "Checked=False" verschiedene Symbole verwenden wollen, brauchen sie auch je 2 Picture-Boxes (mit Index 0 und 1).

WICHTIG: Die Icons müssen die Größe 13x13 Pixel haben, Handarbeit mit einem Bildbearbeitungsprogramm ist also nötig. Wenn Sie transparente Farben festlegen wollen, speichern Sie Ihre Symbole am besten im GIF-Format.

Jetzt fehlt nur noch der Code:

' API-Deklarationen
Private Declare Function GetMenu Lib "user32" ( _
  ByVal hwnd As Long) As Long
 
Private Declare Function GetSubMenu Lib "user32" ( _
  ByVal hMenu As Long, _
  ByVal nPos As Long) As Long
 
Private Declare Function SetMenuItemBitmaps Lib "user32" ( _
  ByVal hMenu As Long, _
  ByVal nPosition As Long, _
  ByVal wFlags As Long, _
  ByVal hBitmapUnchecked As Long, _
  ByVal hBitmapChecked As Long) As Long
 
Const MF_BYPOSITION = &H400&
 
Private lngHandle As Long
Private lngID As Long

Private Sub Form_Load()
  ' Bezug zur Menüleiste ermitteln
  lngHandle = GetMenu(Me.hwnd)
 
  ' Bezug zum Menü festlegen, in dem die Icons
  ' plaziert werden sollen
  ' (Index beginnt mit 0)
  lngID = GetSubMenu(lngHandle, 0)
 
  ' Icons ins Menü laden
  ' 1. Icon für UNCHECKED
  ' 2. Icon für CHECKED
  ' 
  ' Wenn nur 1 Icon gebraucht wird, für beide Zustände
  ' dasselbe Symbol festlegen
  SetMenuItemBitmaps lngID, 0, MF_BYPOSITION, _
    picIcon1(0).Picture, picIcon1(1).Picture
  SetMenuItemBitmaps lngID, 1, MF_BYPOSITION, _
    picIcon2(0).Picture, picIcon2(1).Picture
End Sub