vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: HTML/Internet/Netzwerk · Internet / Browser / IE   |   VB-Versionen: VB4, VB5, VB608.10.02
Alle IE-Fenster schließen

Dieses Beispiel zeigt, wie sich per VB alle geöffneten Internet Explorer Fenster schließen lassen.

Autor:   Dieter OtterBewertung:  Views:  30.919 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Das nachfolgende Beispiel zeigt, wie sich alle geöffneten Internet Explorer Fenster schließen lassen. Hierzu werden alle Fenster "durchlaufen" und anhand der Fensterhandles die jeweiligen Klassennamen ermittelt. Lautet der Klassenname (ClassName) IEFrame, handelt es sich um ein IE-Fenster. Über die SendMessage-API wird dann das Fenster anhand des Fensterhandles geschlossen.

Das ganze sieht dann wie folgt aus.

Erstellen Sie ein neues Projekt und platzieren auf die Form einen CommandButton. Im Allgemein-Teil der Form werden zunächst die API-Funktionen und Konstanten deklariert:

Option Explicit
 
' zunächst die benötigten API-Deklarationen
Private Declare Function GetWindow Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal wCmd As Long) As Long
 
Private Declare Function GetClassName Lib "user32" _
  Alias "GetClassNameA" ( _
  ByVal hwnd As Long, _
  ByVal lpClassName As String, _
  ByVal nMaxCount As Long) As Long
 
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Any) As Long
 
Const WM_SYSCOMMAND = &H112
Const SC_CLOSE = &HF060
Const LNULL = 0&
 
Const GW_HWNDFIRST = 0
Const GW_HWNDNEXT = 2

Beim Klick auf die Schaltfläche sollen alle IE-Fenster geschlossen werden:

Private Sub Command1_Click()
  ' alle offenen IE-Fenster schließen
  Dim lRetVal As Long
  Dim sClassName As String
  Dim CurHWnd As Long
 
  CurHWnd = GetWindow(hwnd, GW_HWNDFIRST)
  Do While CurHWnd <> 0
    ' Klassennamen ermitteln
    sClassName = String$(256, " ")
    lRetVal = GetClassName(CurHWnd, sClassName, 255)
    sClassName = Left$(sClassName, InStr(sClassName, _
      Chr$(0)) - 1)
 
    If sClassName = "IEFrame" Then
      ' Explorer-Fenster gefunden - jetzt schließen
      lRetVal = SendMessage(CurHWnd, WM_SYSCOMMAND, _
        SC_CLOSE, LNULL)
    End If
 
    ' Handle des nächsten Fensters
    ' 0, wenn kein weiteres Fenster vorhanden
    CurHWnd = GetWindow(CurHWnd, GW_HWNDNEXT)
  Loop
End Sub



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.