Flüssig scrollendes Label (Winamp Like) Eine Label, das in einem begrenzten Bereich vor und zurück scrollt
Autor:   Frederik Wolter	Bewertung:     [ Jetzt bewerten ]	Views:  4.844
ohne Homepage	System:  Win9x, WinNT, Win2000, WinXP, Vista	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 25 Bewertung insgesamt: mittelmäßig Durchschnittliche Bewertung: 2.2 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Es gibt viele verschiedene Varianten von scrollenden Texten mit den unterschiedlichsten Lösungen. Oftmals werden hierbei die im Label enthaltenen Texte selbst manipuliert, wodurch es dann zu unerwünschten Effekte kommt (unregelmäßiges scrolling, o.ä.).

Nachfolgende Variante benötigt zur Erstellung einen Timer, eine PictureBox und ein in der Picturebox enthaltenes Label und sorgt für ein flüssiges Hin- und Herscrollen. Außerdem macht der Scrolleffekt eine kleine Pause, sobald der Text eines der beiden Enden erreicht hat.

Starten Sie ein neues Projekt und platzieren auf die Form folgende Controls:

picTitle [PictureBox]
- Eigenschaften beliebig

lblTitle [Label]
- Autosize = True

tmrAnimate [Timer]
- Interval = 100- Enabled = False

Code:

Option Explicit
 
' Steuervariablen für die Animation
Private ScrollDir As Boolean
Private DoScroll As Boolean
Private ScrollCounter As Integer
Private ScrollPixels as Single
Private ScrollPause as Long

"ScrollPixels" steht für die Anzahl an Pixeln pro scrolling. "ScrollPause" definiert, wie viele Intervalle das Label pausiert.

Private Sub Form_Load()
  ' Label oben links in der PictureBox positionieren
  lblTitle.Move 0, 0
  lblTitle.Visible = False
 
  ' Größe festlegen
  picTitle.Width = 2500
 
  ' Text, der im Label angezeigt werden soll
  lblTitle.Caption = "vb@rchiv · Das große Visual Basic Archiv · " & _
    "http://www.vbarchiv.net"
End Sub

Private Sub lblTitle_Change()
  ' Eigenschaften festlegen
  ScrollPixels = 1
  ScrollCounter = 0
  ScrollPause = 5
 
  ' Timer starten?
  If lblTitle.Width > picTitle.Width Then
    tmrAnimate.Enabled = True
  Else
    tmrAnimate.Enabled = False
  End If
  lblTitle.Visible = True
End Sub

Private Sub tmrAnimate_Timer()
  With lblTitle
    ' nach rechts oder nach links scrollen?
    If .Left + .Width > picTitle.Width And .Left >= 0 Then
      ScrollDir = True
      DoScroll = False
    ElseIf .Left + .Width <= picTitle.Width And .Left <= 0 Then
      ScrollDir = False
      DoScroll = False
    End If
 
    ' Zeit-Intervall prüfen
    If DoScroll = False Then
      ScrollCounter = ScrollCounter + 1
      If ScrollCounter >= ScrollPause Then
        DoScroll = True
        ScrollCounter = 0
      End If
    End If
 
    ' Scrollvorgang starten (Label-Position verschieben)
    If ScrollDir = True Then
      .Left = .Left - Screen.TwipsPerPixelX * ScrollPixels
    Else
      .Left = .Left + Screen.TwipsPerPixelX * ScrollPixels
    End If
  End With
End Sub