vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Top-Preis! AP-Access-Tools-CD Volume 1  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Datenbanken · ADO   |   VB-Versionen: VB5, VB622.10.04
SQL Syntax überprüfung (ADO)

Mit dieser Funktion lässt sich die SQL-Syntax für den MS SQL-Server auf Korrektheit überprüfen.

Autor:   Roland WutzkeBewertung:     [ Jetzt bewerten ]Views:  16.042 
www.vb-power.netSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Wer mit MS SQL-Servern arbeitet, kennt die Möglichkeit über den Query Analyzer sein SQL Statement zu überprüfen, bevor es ausgeführt wird. Es wäre doch eine feine Sache, wenn wir diese Funktionalität dem Anwender in unserem Programm auch zur Verfügung stellen könnten.

Doch wie macht der Query Analyzer das, und wie kann man es in VB umsetzen?

Eigentlich ganz einfach. Wir versetzen den SQL-Server in den "NOEXEC" Modus. Damit wird kein SQL Statement ausgeführt, jedoch wird die Syntax überprüft.

Fügen Sie den nachfolgenden Code in ein Modul ein:

' SQL-Syntax-Check
Public Function SQLCheck(ActiveConn As ADODB.Connection, _
  ByVal sSQL As String) As Boolean
 
  Dim oCmd As New ADODB.Command
  Dim oRSCmd As ADODB.Recordset
 
  ' Connection überprüfen
  If ActiveConn Is Nothing Then Exit Function
  On Error GoTo SQLCheck_Error
 
  With oCmd
    ' Command initialisieren
    .ActiveConnection = ActiveConn
    .CommandType = adCmdText
 
    ' SQL-Ausführung unterdrücken
    .CommandText = "SET NOEXEC ON"
    .Execute
 
    ' SQL Syntax prüfen
    .CommandText = sSQL
    Set oRSCmd = .Execute
 
    ' SQL Ausführung wieder aktivieren
    .CommandText = "SET NOEXEC OFF"
    .Execute
  End With
 
  ' Command und Recodset terminieren
  Set oCmd = Nothing
  Set oRSCmd = Nothing
 
  ' Rückgabewert setzen
  SQLCheck = True
  Exit Function
 
SQLCheck_Error:
  ' Syntaxfehler ausgeben
  MsgBox Err.Description, vbInformation
 
  ' Command terminieren
  If Not oCmd Is Nothing Then
    oCmd.CommandText = "SET NOEXEC OFF"
    oCmd.Execute
    Set oCmd = Nothing
  End If
 
  ' Recordset terminieren
  If Not oRSCmd Is Nothing Then _
    Set oRSCmd = Nothing
 
  ' Rückgabewert setzen
  SQLCheck = False
End Function

Übergeben Sie der Funktion die aktive Connection zum Server und das zu prüfende Statement. Im folgenden Beispiel wird die Connection "oConn" und der Text aus der Textbox "txtSQL" überprüft.

If SQLCheck(oConn, txtSQL.Text) Then
  MsgBox "SQL Syntax ok.", vbInformation
End If

Hinweis:
Wenn Sie T-SQL Anweisungsblöcke, die mit "Go" getrennt sind, überprüfen möchten, so führt diese Funktion nur den ersten Block bis zum "Go" aus. Splitten Sie hierzu am besten die Blöcke und überprüfen Sie diese dann einzeln.
 

Dieser Tipp wurde bereits 16.042 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel