vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v2.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2015
 
zurück
Rubrik: COM/OLE/Registry/DLL · Sonstiges   |   VB-Versionen: VB5, VB627.10.04
Pfad der aufrufenden Anwendung ermitteln (COM-Objekt)

Dieser Tipp verrät, wie man in einem COM-Objekt (bspw. ActiveX-DLL) den Pfad einer aufrufenden Anwendung ermittelt.

Autor:   MartoengBewertung:     [ Jetzt bewerten ]Views:  7.915 
www.martoeng.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Summer-Special bei Tools & Components!
Gute Laune Sommer bei Tools & Components
Top Summer-Special - Sparen Sie teilweise über 100,- EUR
Alle sev-Entwicklerkomponenten und Komplettpakete jetzt bis zu 25% reduziert!
zum Beispiel:
  • Developer CD nur 455,- EUR statt 569,- EUR
  • sevDTA 2.0 nur 224,30 EUR statt 299,- EUR
  •  
  • vb@rchiv   Vol.6 nur 18,70 EUR statt 24,95 EUR
  • sevCoolbar 3.0 nur 58,70 EUR statt 69,- EUR
  • - Werbung -Und viele weitere Angebote           Aktionspreise nur für kurze Zeit gültig

    Den Pfad einer Anwendung ermitteln - das geht doch einfach wird sich jeder denken. Auch aus einer DLL heraus ist es noch keine Schwierigkeit.

    Was aber, wenn Sie eine ActiveX-DLL geschrieben haben, und Sie den Pfad der aufrufenden, also instanzierenden Anwendung ermitteln wollen? Da hilft dieser Tipp weiter.

    Option Explicit
     
    ' Benötigte API-Deklarationen
    Private Declare Function GetFullPathName Lib "kernel32" _
      Alias "GetFullPathNameA" ( _
      ByVal lpFileName As String, _
      ByVal nBufferLength As Long, _
      ByVal lpBuffer As String, _
      ByVal lpFilePart As String) As Long
     
    Private Declare Function CreateToolhelpSnapshot Lib "kernel32" _
      Alias "CreateToolhelp32Snapshot" ( _
      ByVal lFlgas As Long, _
      ByVal lProcessID As Long) As Long
     
    Private Declare Function ProcessFirst Lib "kernel32" _
      Alias "Process32First" ( _
      ByVal hSnapshot As Long, _
      uProcess As PROCESSENTRY32) As Long
     
    Private Declare Function ProcessNext Lib "kernel32" _
      Alias "Process32Next" ( _
      ByVal hSnapshot As Long, _
      uProcess As PROCESSENTRY32) As Long
     
    Private Declare Sub CloseHandle Lib "kernel32" ( _
      ByVal hPass As Long)
     
    Private Declare Function GetCurrentProcessId Lib "kernel32.dll" () As Long 
     
    Private Const TH32CS_SNAPPROCESS As Long = 2&
    Private Const MAX_PATH As Long = 260
     
    Private Type PROCESSENTRY32
      dwSize As Long
      cntUsage As Long
      th32ProcessID As Long
      th32DefaultHeapID As Long
      th32ModuleID As Long
      cntThreads As Long
      th32ParentProcessID As Long
      pcPriClassBase As Long
      dwflags As Long
      szexeFile As String * MAX_PATH
    End Type
    ' Pfad der aufrufenden Anwendung ermitteln
    Private Function GetInstancePath() As String
      Dim lProcessID As Long
      Dim lSnapshot As Long
      Dim uProcess As PROCESSENTRY32
      Dim lProcessFound As Long
      Dim i As Integer
      Dim sEXEName As String
     
      ' aktuelle Prozess-ID ermitteln
      lProcessID = GetCurrentProcessId
      lSnapshot = CreateToolhelpSnapshot(TH32CS_SNAPPROCESS, 0&)
     
      ' Fehler?
      If lSnapshot = -1 Then Exit Function
     
      ' uProcess-Struktur füllen
      With uProcess
        .dwSize = Len(uProcess)
     
        ' alle aktiven Prozesse durchlaufen
        lProcessFound = ProcessFirst(lSnapshot, uProcess)
        Do While lProcessFound
          If .th32ProcessID = lProcessID Then
            ' ProzessID gefunden
            ' jetzt EXE-Name ermitteln
            If InStr(.szexeFile, Chr$(0)) > 0 Then
              sEXEName = Left$(.szexeFile, InStr(.szexeFile, Chr$(0)) - 1)
            End If
            Exit Do
          Else
            ' ...weitersuchen...
            lProcessFound = ProcessNext(lSnapshot, uProcess)
          End If
        Loop
      End With
     
      ' vollständigen Pfad ermitteln    
      Dim nBuffer As String
      Dim nFilePart As String
      Dim nLen As Long
     
      nBuffer = Space$(255)
      nLen = GetFullPathName(sEXEName, Len(nBuffer), nBuffer, nFilePart)
      If nLen Then sEXEName = Left$(nBuffer, nLen)
     
      GetInstancePath = sEXEName
    End Function

    Dieser Tipp wurde bereits 7.915 mal aufgerufen.

    Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

    Über diesen Tipp im Forum diskutieren
    Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

    Neue Diskussion eröffnen

    nach obenzurück


    Anzeige

    Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
    (einschl. Beispielprojekt!)

    Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
    - nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
    - Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
    Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
     
       

    Druckansicht Druckansicht Copyright ©2000-2015 vb@rchiv Dieter Otter
    Alle Rechte vorbehalten.
    Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

    Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel