vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
vb@rchiv Offline-Reader - exklusiv auf der vb@rchiv CD Vol.4  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2014
 
zurück
Rubrik: Controls · StatusBar/ProgressBar   |   VB-Versionen: VB4, VB5, VB606.12.04
Objekte in der StatusBar

Wie man beliebige Objekte in der StatusBar anzeigen kann, das erfahren Sie hier.

Autor:   Roland WutzkeBewertung:     [ Jetzt bewerten ]Views:  10.545 
www.vb-power.netSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8 Beispielprojekt auf CD 

Die Statusbar - ein wichtiger Begleiter in jedem VB-Projekt - dient in der Regel zur Anzeige von Programminformationen. Wie wäre es aber, wenn wir beliebige Steuerelemente in der Statusbar platzieren könnten.

Eine TextBox, eine CheckBox , eine Combo- oder DriveListBox. Alles kein Problem mehr.
Oder aber statten Sie die StatusBar mit einem Hyperlabel aus. Der Anwender erreicht Sie so direkt per Mail oder gelangt auf Ihre Homepage.

Die nachfolgende Routine basiert im Ursprung auf dem Tipp "ProgressBar in der StatusBar" und wurde nur geringfügig geändert. Erweitert wurde die Möglichkeit, das Objekt im Panel zu positionieren. Optional können beim Aufruf der Routine die X- und Y-Verschiebung des Objekts relativ zur linken oberen Ecke des Panels angegeben werden.

Das Ergebnis kann dann so aussehen:

Fügen Sie nachfolgenden Code in ein Modul ein.

' **********************************************************************
' *
' *   Diese Funktion stammt im Ursprung aus dem vbarchiv
' *   von Dieter Otter und wurde von VB-Power.net modifiziert.
' *   Ursprünglicher Tipp: ProgressBar in der StatusBar
' *   von Dietmar G. Bayer, www.vbarchiv.net
' *
' *   SetObjectToStatusBar - beliebiges Objekt in der StatusBar
' *
' *   Dezember 2004, VB-Power.net   www.vb-power.net
' *
' **********************************************************************
 
Option Explicit
 
' Benötigte API-Deklarationen
Private Declare Function SetParent Lib "user32" ( _
  ByVal hWndChild As Long, _
  ByVal hWndNewParent As Long) As Long
 
Private Declare Function SendMessageAny Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal msg As Long, _
  ByVal wParam As Long, _
  lParam As Any) As Long
 
Private Declare Function MoveWindow Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal x As Long, _
  ByVal y As Long, _
  ByVal nWidth As Long, _
  ByVal nHeight As Long, _
  ByVal bRepaint As Long) As Long
 
Private Type RECT
  Left As Long
  Top As Long
  Right As Long
   Bottom As Long
End Type
 
Private Const WM_USER As Long = &H400
Private Const SB_GETRECT As Long = (WM_USER + 10)
' Objekt in StatusBar setzen
Public Sub SetObjectToStatusBar(ByVal hWnd_Obj As Long, _
  ByVal hWnd_SBar As Long, _
  ByVal nPanel As Long, _
  Optional XPos As Long = 0, _
  Optional YPos As Long = 0)
 
  Dim cXPos As Long
  Dim cYPos As Long
  Dim R As RECT
 
  ' Border in Pixel
  Const cBorder As Long = 1
 
  ' Screenkoordinaten in Pixel umrechnen
  cXPos = XPos / Screen.TwipsPerPixelX
  cYPos = YPos / Screen.TwipsPerPixelY
 
  ' Ausmaße des Panel ermitteln
  SendMessageAny hWnd_SBar, SB_GETRECT, nPanel - 1, R
 
  ' Objekt ein neues zuhause geben...
  SetParent hWnd_Obj, hWnd_SBar
 
  ' ... und korrekt positionieren
  MoveWindow hWnd_Obj, R.Left + cXPos + cBorder, _
    R.Top + cYPos + cBorder, _
    R.Right - R.Left - cXPos - cBorder, _
    R.Bottom - R.Top - cYPos - cBorder, True
End Sub

Einzige Voraussetzung, die das Objekt erfüllen muss: es muss über eine hWnd-Eigenschaft verfügen. Objekte die das nicht haben, wie z.B. ein Label, setzen Sie erst in eine PictureBox und dann die PictureBox in die StatusBar und schon findet auch ein (Hyper)Label platz in der Statusbar.

Der Aufruf der Routine sieht etwa so aus:

SetObjectToStatusBar Check1.hwnd, StatusBar1.hwnd, 4, 150

Erläuterung: Die Checkbox (Check1) wird der StatusBar1 auf Panel Nummer 4 übergeben. Der X-Abstand beträgt 150 Twips.
 

Dieser Tipp wurde bereits 10.545 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2014 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel