vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Zippen wie die Profis!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Controls · TextBox & RichTextBox   |   VB-Versionen: VB608.12.04
Auto-Indent für die (RTF)TextBox

Dieser Tipp zeigt, wie sich eine AutoIndent-Funktion für die Standard-TextBox bzw. für das RichTextBox-Control realisieren lässt - so wie man es von der VB-IDE her kennt und gewohnt ist.

Autor:   Jürgen SorkoBewertung:     [ Jetzt bewerten ]Views:  16.905 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

In unserem heutigen Tipp möchten wir Ihnen eine "AutoIndent"-Funktion für die Standard-TextBox bzw. für das RichTextBox-Control vorstellen - so wie man es bspw. von der VB-IDE her kennt und gewohnt ist.

Die autoIndent-Funktion fügt hierbei an der aktuellen Position exakt so viele Leerzeichen in den Text ein, wie die vorherige Zeile führende Leerzeichen hat. Dies kann man verwenden um z.B. beim Drücken der ENTER-Taste den Text automatisch einzurücken.

Die benötigenten Funktionen:

' Rückt den Text ein
Public Sub autoIndent(oTextBox As Object)
  Dim nSpaces As Long
 
  With oTextBox
    ' Anzahl Leerzeichen der vorigen Zeile
    nSpaces = getLastSpaces(.Text, .SelStart)
 
    ' Zeilenumbruch und Anzahl ermittelter Leerzeichen einfügen
    .SelText = vbNewLine & Space$(nSpaces)
  End With
End Sub
' Gibt die Anzahl der führenden Leerzeichen der
' vorigen Zeile im RichTextBox-Control aus
Private Function getLastSpaces(ByVal sText As String, _
  nCurPos As Long) As Long
 
  ' Fehlerbehanldung aktivieren (sicher ist sicher)
  On Error Resume Next
 
  Dim nPos As Long
  Dim nSpaces As Long
 
  nPos = InStrRev(Left$(sText, nCurPos), vbNewLine)
  If nPos > 0 Then
    nPos = nPos + 2
    While Mid$(sText, nPos, 1) = " "
      nSpaces = nSpaces + 1
      nPos = nPos + 1
    Wend
  End If
 
  getLastSpaces = nSpaces
End Function

Die Funktion "autoIndent" erwartet als Parameter ein TextBox-Control. Hierbei kann es sich sowohl um eine Standard TextBox, als auch um ein RichTextBox-Control handelt.

Ein kleines Beispiel:
Platzieren Sie auf die Form ein RichTextBox-Control und fügen obigen Code in den Codeteil der Form ein.
Beim Drücken der ENTER-Taste soll die nächste Zeile autom. um die gleiche Anzahl Leerzeichen, wie die aktuelle Zeile, eingerückt werden.

Private Sub RichTextBox1_KeyPress(KeyAscii As Integer)
  If KeyAscii = vbKeyReturn Then
    ' Beim Drücken von Return, neuen Absatz autom. einrücken
    KeyAscii = 0
    autoIndent RichTextBox1
  End If
End Sub