vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevDataGrid - Gönnen Sie Ihrem SQL-Kommando diesen krönenden Abschluß!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Dateisystem · Dateien - allgemein   |   VB-Versionen: VB.NET11.03.05
Laufwerk(e) nach bestimmter Datei durchsuchen

Mit dieser VB.NET Klasse können Sie ein Laufwerk oder auch die gesamte Festplatte nach einer bestimmten Datei durchsuchen.

Autor:   WaldiMaywoodBewertung:     [ Jetzt bewerten ]Views:  20.277 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Heute möchten wir Ihnen ein Klassenmodul vorstellen, mit dem sich ein einzelnes Laufwerk oder auch die gesamte Festplatte (alle logischen Laufwerke) nach einer bestimmten Datei durchsuchen lässt.

Erstellen Sie ein neues Projekt (Windows-Anwendung) und fügen dem Projekt ein Klassemodul mit folgendem Code hinzu.

Public Class SearchFile
  Inherits Object
  Private m_FileName As String
  Private m_Log As Boolean
  Private m_Drives() As String
  Private m_sw As IO.StreamWriter
  Private m_Abort As Boolean
  Public Event CurrentFile(ByVal FileName As String, ByVal IsEqual As Boolean)
 
  ' Vorgang abbrechen
  Public Sub Abort()
    Me.m_Abort = True
  End Sub
 
  ' Klassen-Initialisierung
  Public Sub New(ByVal FileName As String, ByVal Drives() As String, ByVal Log As Boolean)
    MyBase.New()
    Me.m_FileName = FileName
    Me.m_Log = Log
    Me.m_Drives = Drives
  End Sub
 
  ' Suchvorgang starten
  Public Sub Search()
    Try
      Me.m_Abort = False
      If Me.m_Log Then m_sw = New IO.StreamWriter("log.txt", False)
      For Each d As String In Me.m_Drives
        Me.Search(d)
        If Me.m_Abort Then Return
      Next
    Finally
      If Not m_sw Is Nothing Then
        m_sw.Close()
      End If
    End Try
  End Sub
 
  ' aktuelle Datei in LogFile speichern
  Private Sub Log(ByVal CurrentFile As String)
    If Not Me.m_Log Then Return
    m_sw.WriteLine(CurrentFile)
  End Sub
 
  ' Vergleich, ob es sich bei der aktuellen 
  ' Datei um die gesuchte Datei handelt
  Private Sub IsEqual(ByVal CurrentItem As String)
    RaiseEvent CurrentFile(CurrentItem, _
      Me.m_FileName.ToUpper.Equals(IO.Path.GetFileName(CurrentItem).ToUpper))
  End Sub
 
  ' Verzeichnis durchsuchen
  Private Sub SearchFile(ByVal Dir As String)
    For Each f As String In IO.Directory.GetFiles(Dir)
      Me.Log(f)
      Me.IsEqual(f)
      If Me.m_Abort Then Return
    Next
  End Sub
 
  ' alle Verzeichnisse ermitteln und Suchvorgang ausführen
  Private Sub Search(ByVal Dir As String)
    Try
      SearchFile(Dir)
      For Each d As String In IO.Directory.GetDirectories(Dir)
        Try
          If Me.m_Abort Then Return
          Search(d)
        Catch ex As Exception
          Debug.WriteLine(ex.Message)
        End Try
      Next
    Catch ex As Exception
      Debug.WriteLine(ex.Message)
    End Try
  End Sub
End Class

Platzieren Sie auf die Form eine TextBox (TextBox1), zwei Buttons (Button1 und Button2), ein Label-Control (Label1) und ein ListBox-Control (ListBox1). Die TextBox dient zur Eingabe der gesuchten Datei. Durch Klick auf den 1. Button wird der Suchvorgang gestartet. Alle Treffer sollen in der ListBox aufgelistet werden. Das Label-Control dient zur Anzeige des Verzeichnisses, das aktuell durchsucht wird. Durch Klick auf den 2. Button soll die Möglichkeit gegeben werden, den Suchvorgang abzubrechen.

Und hier der Code für die Form1:

Public Class Form1
  Inherits System.Windows.Forms.Form
 
  Dim f As SearchFile
 
  Private Sub Button1_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button1.Click
 
    ' alle logischen LW nach der Datei durchsuchebn, 
    ' die in der TextBox eingegeben wurde
    f = New SearchFile(TextBox1.Text, System.Environment.GetLogicalDrives, True)
    AddHandler f.CurrentFile, AddressOf CurrentFile
    f.Search()
  End Sub
 
  Private Sub CurrentFile(ByVal FileName As String, ByVal IsEqual As Boolean)
    ' Pfad extrahieren und im Label-Control anzeigen
    Dim sPath As String = IO.Path.GetDirectoryName(FileName)
    If Label1.Text <> sPath Then
      Label1.Text = sPath
      Application.DoEvents()
    End If
 
    ' Treffer der ListBox hinzufügen
    If IsEqual Then
      Me.ListBox1.Items.Add("Found: " + FileName)
      Application.DoEvents()
      ' Falls nach dem 1. Treffer der Vorgang abgebrochen 
      ' werden soll, einfach die Abort-Methode aufrufen
      ' f.Abort()
    End If
  End Sub
 
  Private Sub Button2_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button2.Click
 
    ' Bei Klick auf den 2. Button, Vorgang abbrechen
    f.Abort()
  End Sub
End Class

Dieser Tipp wurde bereits 20.277 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel