TextWrap - autom. Textumbruch nach x Zeichen Mit dieser Funktion lassen sich lange Texte auf mehrere Zeilen umbrechen, wobei die maximale Zeilenlänge angegeben werden kann.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  2.004
www.tools4vb.de	System:  Win9x, WinNT, Win2000, WinXP, Vista	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 6 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 5.0 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Heute möchten wir Ihnen eine Funktion vorstellen, mit der sich lange Texte (mit oder ohne Zeilenumbrüche) auf mehrere Zeilen verteilen lassen, wobei die maximale Länge der Zeilen als Parameter angegeben wird.

' autom. Textumbruch nach x-Zeichen
Public Function TextWrap(ByVal sText As String, _
  Optional ByVal nMaxLen As Long = 72) As String
 
  Dim nStart As Long
  Dim nPos As Long
  Dim sLine As String
 
  ' nach harten Zeilenumbrüchen suchen
  nStart = 1
  Do
    nPos = InStr(nStart, sText, vbNewLine)
    If nPos > 0 Then
      ' jetzt Zeile umbrechen
      sLine = Mid$(sText, nStart, nPos - nStart)
      TextWrap = TextWrap & LineWrap(sLine, nMaxLen) & vbNewLine
      nStart = nPos + Len(vbNewLine)
    End If
  Loop Until nPos = 0
 
  If nStart <= Len(sText) Then
    ' Letzte Zeile muss ggf. noch umgebrochen werden
    TextWrap = TextWrap & LineWrap(Mid$(sText, nStart), nMaxLen)
  End If
End Function

Private Function LineWrap(ByVal sLine As String, _
  ByVal nMaxLen As Long) As String
 
  Dim nPos As Long
 
  ' Solange die Zeile länger als die gewünschte Länge ist
  Do While Len(sLine) > nMaxLen
    ' nach Leerzeichen suchen
    nPos = InStrRev(sLine, " ", nMaxLen)
    If nPos = 0 Then nPos = nMaxLen
 
    ' Zeile an der gefundenen Stelle umbrechen
    LineWrap = LineWrap & RTrim$(Left$(sLine, nPos)) & vbNewLine
    sLine = LTrim$(Mid$(sLine, nPos + 1))
  Loop
  LineWrap = LineWrap & sLine
End Function

Beispiel für den Aufruf:

Dim sText As String
 
sText = "Dies ist ein etwas längerer Text, " & _
  "der autom. nach 25 Zeichen umgebrochen werden soll." & vbCrLf & _
  "Und das ist dann die nächste Zeile, die umgebrochen wird."
 
' autom. Zeilenumbruch nach 30 Zeichen
MsgBox TextWrap(sText, 30)