vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Blitzschnelles Erstellen von grafischen Diagrammen!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Controls · ListBox & ComboBox   |   VB-Versionen: VB.NET26.11.07
ListBox mit laufender ToolTip-Anzeige (.NET)

Diesmal zeigen wir Ihnen, wie sich in der Standard-ListBox der Eintrag unter dem Mauszeiger bei Bedarf als ToolTip anzeigen lässt.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  15.733 
www.tools4vb.deSystem:  WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Heute zeigen wir Ihnen eine Möglichkeit, wie sich in der Standard-ListBox von VB.NET der Eintrag unter dem Mauszeiger bei Bedarf als ToolTip anzeigen lässt, d.h. der ToolTip wird nur dann angezeigt, wenn der Eintrag unter dem Mauszeiger nicht vollständig lesbar ist.

Erstellen Sie hierzu ein neues Projekt, platzieren auf die Form eine ListBox (ListBox1) und fügen nachfolgenden Code in das Codefenster der Form ein:

' ToolTip-Objekt
Dim oToolTip As New ToolTip
Private Sub Form1_Load(ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles MyBase.Load
 
  ' ListBox vorbereiten
  With ListBox1
    .Font = New Font("Verdana", 10, FontStyle.Regular)
    .Width = 150
  End With
 
  ' ein paar Testeinträge erstellen
  With ListBox1.Items
    .Add("Dies ist ein normaler Text")
    .Add("Dies ist ein etwas längerer Text")
    .Add("Kurz")
    .Add("Und noch einmal ein etwas längerer Text")
  End With
End Sub
Private Sub ListBox1_MouseMove(ByVal sender As Object, _
  ByVal e As System.Windows.Forms.MouseEventArgs) _
  Handles ListBox1.MouseMove
 
  Dim sToolTip As String = ""
 
  ' ToolTip nur anzeigen, wenn keine Maustaste gedrückt ist
  If e.Button = Windows.Forms.MouseButtons.None Then
    With ListBox1
      ' ListIndex anhand der Mausposition ermitteln
      Dim p As Point = .PointToClient(Cursor.Position)
      Dim index As Integer = .IndexFromPoint(p)
      If index >= 0 Then
        ' Text des Eintrags unter dem Mauszeiger
        Dim sText As String = .Items(index).ToString
 
        ' Prüfen, ob Text vollständig angezeigt wird
        Using g As Graphics = .CreateGraphics
          ' Breite des vollständigen Textes ermitteln
          Dim nWidth As Integer = CInt(g.MeasureString( _
            sText, .Font, 0, StringFormat.GenericTypographic).Width)
 
          ' ermittelte Breite mit Innenbereich der ListBox vergleichen
          If nWidth > .ClientRectangle.Width Then
            ' Text als ToolTip anzeigen
            sToolTip = sText
          End If
        End Using
      End If
    End With
  End If
 
  ' ToolTip zuweisen
  If oToolTip.GetToolTip(ListBox1) <> sToolTip Then
    oToolTip.SetToolTip(ListBox1, sToolTip)
  End If
End Sub
Private Sub ListBox1_MouseLeave(ByVal sender As Object, _
  ByVal e As System.EventArgs) Handles ListBox1.MouseLeave
 
  ' ToolTip zurücksetzen
  oToolTip.SetToolTip(ListBox1, "")
End Sub

Dieser Tipp wurde bereits 15.733 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel