Textausgabe direkt auf die Form Eine Funktion, mit der sich ein Text unter Angabe der Position, Schriftgröße und Farbe direkt auf die Form schreiben lässt.
Autor:   Norbert Grimm	Bewertung:     [ Jetzt bewerten ]	Views:  4.795
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Vista, Win7	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 11 Bewertung insgesamt: nützlich Durchschnittliche Bewertung: 3.0 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Mit nachfolgender Funktion lässt sich ein Text unter Angabe der Position, Schriftgröße und Farbe direkt auf die Form schreiben.

' in aktuelles Formular schreiben
'
' die Funktion benutzt die "Print" -Anweisung, um direkt in ein
' geöffnetes Formular zu schreiben
'
Function WriteInForm(ByRef frmObj As VB.Form, _
  ByVal sText As String, _
  ByVal nSize As Long, _
  ByVal nBold As Boolean, _
  ByVal nColor As Long, _
  ByVal xPos As Long, _
  ByVal yPos As Long) As Long
 
  Dim FB      As Boolean  ' FontBold
  Dim FC      As Long     ' ForeColor
  Dim FS      As Long     ' FontSize
  Dim Ret     As Long     ' 0 = o.k., <> 0 = Fehler
  Dim errMsg  As String
 
  ' Fehlerroutine
  On Error GoTo Err_WIF
 
  With frmObj
    ' Schriftgrösse speichern
    FS = .FontSize
    ' neue Schriftgröße setzen, falls angegeben
    If nSize <> 0 Then .FontSize = nSize
 
    ' Schriftattribut "Fett" speichern
    FB = .FontBold
    ' Schrift ggd. auf "Fett" setzen
    .FontBold = nBold
 
    ' Vordergrundfarbe speichern
    FC = .ForeColor
    ' neue Vordergrundfarbe setzen, falls angegeben
    If nColor <> 0 Then .ForeColor = nColor
 
    ' Position für die Textausgabe setzen
    .CurrentX = xPos
    .CurrentY = yPos
 
    ' Text ausgeben
    frmObj.Print sText
 
    ' Schriftgröße, -farbe und Schriftattribut zurücksetzen
    .FontSize = FS
    .FontBold = FB
    .ForeColor = FC
  End With
 
Exit_WIF:
  WriteInForm = Ret
  Exit Function
 
Err_WIF:
  With Err
    Ret = .Number
    errMsg = .Description
    .Clear
  End With
  MsgBox Ret & vbCr & errMsg, , "WriteInForm"
  Resume Exit_WIF
End Function

Anwendungsbeispiel:

WriteInForm Me, "Beispieltext", 12, True, vbRed, 1000, 1000
WriteInForm Me, "Dieser Text wurde direkt auf die Form geschrieben", 10, False, _
  vbBlue, 1000, 1500