vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
SEPA-Dateien erstellen inkl. IBAN-, BLZ-/Kontonummernprüfung  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Drucker   |   VB-Versionen: VB2005, VB200831.10.08
Druckerwarteschlange auslesen

Mit diesem Code lassen sich alle noch anstehenden Druckaufträge in der Druckerwarteschlange auslesen.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  22.766 
www.tools4vb.deSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Sie möchten alle noch anstehenden Druckaufträge in der Windows Druckerwarteschlange auslesen und gezielt bestimmte Informationen zu den Druckaufträgen ermitteln?

Unter Verwendung von WMI ist das absolut kein Problem.

Erstellen Sie ein neues Projekt und fügen einen Verweis auf die System.Management-Assembly (System.Management.dll) hinzu.

Platzieren Sie auf die Form ein ListView-Control und ein Button und fügen nachfolgenden Code in den Codeteil der Form ein:

Imports System.Management
Public Class Form1
  Private Sub Form1_Load(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles MyBase.Load
 
    ' ListView vorbereiten
    With ListView1
      With .Columns
        .Add("Dokument", 200)
        .Add("Drucker", 100)
        .Add("Status", 70)
        .Add("Seiten", 50, HorizontalAlignment.Center)
        .Add("Größe", 60, HorizontalAlignment.Right)
        .Add("Besitzer", 150)
      End With
      .View = View.Details
      .FullRowSelect = True
    End With
  End Sub
  Private Sub Button1_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button1.Click
 
    ' Druckerwarteschlange auslesen und in ListView eintragen
    Me.Cursor = Cursors.WaitCursor
    With ListView1
      .Items.Clear()
      .BeginUpdate()
 
      ' WMI-Abfrage erstellen und ausführen
      Dim sQuery As String = "SELECT * FROM Win32_PrintJob"
      Dim Jobs As New ManagementObjectSearcher(sQuery)
 
      ' Schleife durchlaufen und Infos zu den Druckaufträgen ermitteln
      For Each Job As ManagementObject In Jobs.Get()
        Dim Document As String = WMIGetInfo(Job, "Document")
        Dim Printer As String = WMIGetInfo(Job, "DriverName")
        Dim Status As String = WMIGetInfo(Job, "JobStatus")
        Dim Pages As String = WMIGetInfo(Job, "PagesPrinted") & " von " & _
          WMIGetInfo(Job, "TotalPages")
        Dim Size As Integer = Val(WMIGetInfo(Job, "Size"))
        Dim Owner As String = WMIGetInfo(Job, "Owner")
 
        With .Items.Add(Document)
          .SubItems.Add(Printer)
          .SubItems.Add(Status)
          .SubItems.Add(Pages)
          .SubItems.Add(FormatNumber(Size / 1024, 1, , , TriState.True) & " KB")
          .SubItems.Add(Owner)
        End With
      Next
 
      .EndUpdate()
    End With
    Me.Cursor = Cursors.Default
  End Sub
  ''' <summary>
  ''' Hilfsfunktion. Gibt den Eigenschaftenwert des Objekts zurück, falls vorhanden.
  ''' Ist der Eigenschaftenwert nicht verfügbar, wird ein Leerstring zurückgegeben.
  ''' </summary>
  Private Function WMIGetInfo(ByVal WMIObj As ManagementObject, _
    ByVal Key As String) As String
 
    If Not WMIObj(Key) Is Nothing Then
      Return WMIObj(Key).ToString
    Else
      Return ""
    End If
  End Function
End Class

Beim Klick auf den Button wird die Druckerwarteschlange ausgelesen und die jeweiligen Druckaufträge im ListView aufgelistet.

Dieser Tipp wurde bereits 22.766 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel