vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevDataGrid - Gönnen Sie Ihrem SQL-Kommando diesen krönenden Abschluß!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: HTML/Internet/Netzwerk · Sonstiges   |   VB-Versionen: VB4, VB5, VB602.05.01
Internet-Link auf dem Desktop erstellen

Dieser Tipp zeigt, wie man einen Link zu einer Webseite auf dem Windows-Desktop erstellt.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  15.857 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Der nachfolgende Tipp zeigt, wie man einen Link zu einer bestimmten Webseite direkt auf dem Windows-Desktop erstellt. Gleichzeitig steckt in unserem Tipp auch eine Routine zum Ermitteln des Windows-Desktop-Verzeichnisses.

' API für das Ermitteln des Desktop-Verzeichnisses
Private Declare Function RegOpenKey Lib "advapi32.dll" _
  Alias "RegOpenKeyA" ( _
  ByVal hKey As Long, _
  ByVal lpSubKey As String, _
  phkResult As Long) As Long
 
Private Declare Function RegQueryValueEx Lib "advapi32.dll" _
  Alias "RegQueryValueExA" ( _
  ByVal hKey As Long, _
  ByVal lpValueName As String, _
  ByVal lpReserved As Long, _
  lpType As Long, _
  lpData As Any, _
  lpcbData As Long) As Long
 
Private Declare Function RegCloseKey Lib "advapi32.dll" ( _
  ByVal hKey As Long) As Long
 
Const HKEY_CURRENT_USER = &H80000001
Const REG_SZ = 1
Const KEY_READ = ((&H20000 Or &H1 Or &H8 Or &H10) _
  And (Not &H100000))
 
Const ERROR_SUCCESS = 0&

Die nachfolgende Routine ermittelt das Desktop-Verzeichnis. Hierzu wird "einfach" in der Windows-Registrierdatenbank nachgeschaut und der entsprechende Eintrag ausgelesen.

' Desktop-Verzeichnis ermitteln
Private Function GetDesktopPath() As String
  Dim sValue As String * 256
  Dim hKey As Long
  Dim nType As Long
  Dim lResult As Long
 
  If (RegOpenKey(HKEY_CURRENT_USER, _
    "Software\Microsoft\Windows\CurrentVersion\" & _
    "Explorer\Shell Folders", hKey) = ERROR_SUCCESS) Then
    If (RegQueryValueEx(hKey, "Desktop", 0, nType, _
      ByVal sValue, Len(sValue)) = ERROR_SUCCESS) Then
      If (nType = REG_SZ) Then
        GetDesktopPath = Left(sValue, _
          InStr(sValue, vbNullChar) - 1)
      End If
    End If
    lResult = RegCloseKey(hKey)
  End If
End Function

Um nun einen Internet-Link auf dem Desktop zu speichern, rufen Sie nachfolgende Routine auf und übergeben dieser den Dateinamen (ohne Pfadangabe) und den WWW-Link.

' Internet-Link auf dem Desktop erstellen
Public Sub URLLinkToDesktop(ByVal URLFile As String, _
  ByVal URLLink As String)
 
  Dim F As Integer
  Dim Desktop As String
 
  Desktop = GetDesktopPath()
  F = FreeFile
  Open Desktop + "\" + URLFile For Output As #F
  Print #F, "[InternetShortcut]"
  Print #F, "URL=" & URLLink
  Close #F
End Sub

Beispiel:
Das nachfolgende Beispiel erzeugt ein Link zum vb@rchiv:

URLLinkToDesktop "vbarchiv.url", _
  "http://www.vbarchiv.de"

Dieser Tipp wurde bereits 15.857 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel