vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
vb@rchiv Offline-Reader - exklusiv auf der vb@rchiv CD Vol.4  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Oberfläche · Fenster   |   VB-Versionen: VB609.06.09
Rahmenlose Form mit Maus vergrößern/verkleinern

Formgröße eines Form ohne Rahmen während der Laufzeit mit der Maus vergrößern/verkleinern.

Autor:   JAGBewertung:     [ Jetzt bewerten ]Views:  11.100 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Wenn man ein Form ohne Rahmen (BorderStyle=0) nutzen möchte, hat man hier leider keine Möglichkeit mehr die Größe (wie z.B. bei einem Form mit BorderStyle=2) während der Laufzeit mit der Maus zu vergrößern bzw. zu verkleinern.

Mit nachfolgendem Tipp lässt sich hier aber Abhilfe schaffen.

Erstellen Sie ein Projekt, platzieren auf das Form einen Timer (Timer1) sowie einen CommandButton (cmdAbbruch)und setzen Sie die BorderStyle-Eigenschaft auf 0-Kein.

Fügen Sie anschließend den folgenden Code ein:

Option Explicit
 
' benötigte API-Deklarationen
Private Declare Function GetCursorPos Lib "user32" ( _
  lpPoint As POINTAPI) As Long
 
Private Type POINTAPI
  X As Long
  Y As Long
End Type
 
Dim P As POINTAPI
 
Dim mouBut As Integer
Dim mouPos As Long
Dim oldTop As Long
Dim oldLeft As Long
Private Sub cmbAbbruch_Click()
  ' Beenden
  Timer1.Enabled = False
  Unload Me
End Sub
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  mouBut = 1
 
  ' alte Werte merken
  oldTop = Me.Top
  oldLeft = Me.Left
 
  ' Timer starten
  If Me.MousePointer = 7 Or Me.MousePointer = 9 Then
    Timer1.Interval = 10
    Timer1.Enabled = True
  End If
End Sub
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
  ' aktuelle Mauszeiger-Position
  GetCursorPos P
 
  With Me
    If mouBut = 0 Then
      ' Mousepointer rechts
      If P.X * Screen.TwipsPerPixelX - .Left > .Width - 75 Then
        .MousePointer = 9
        mouPos = 1
 
      ' Mousepointer links
      ElseIf P.X * Screen.TwipsPerPixelX < .Left + 75 Then
        .MousePointer = 9
        mouPos = 2
 
      ' Mousepointer unten
      ElseIf P.Y * Screen.TwipsPerPixelY - .Top > .Height - 75 Then
        .MousePointer = 7
        mouPos = 3
 
      ' Mousepointer oben
      ElseIf P.Y * Screen.TwipsPerPixelY < .Top + 75 Then
        .MousePointer = 7
        mouPos = 4
 
      Else
        ' Mousepointer zurücksetzen
        .MousePointer = 0
      End If
    End If
  End With
End Sub
Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
  ' Timer stoppen
  Timer1.Enabled = False
 
  ' Form darf nicht zu klein werden !
  With Me
    If .Width <= 500 Then
      If mouPos = 2 Then .Left = oldLeft - (560 - .Width)
      .Width = 560
    End If
 
    If .Height <= 500 Then
      If mouPos = 4 Then .Top = oldTop - (560 - .Height)
      .Height = 560
    End If
  End With
 
  ' Button und Positionsmerker rücksetzen
  mouBut = 0
  mouPos = 0
End Sub
Private Sub Timer1_Timer()
  On Error Resume Next
 
  With Me
    ' rechts größer ziehen
    If mouBut = 1 And mouPos = 1 And _
      .MousePointer = 9 And .Width >= 500 Then
 
      .Width = P.X * Screen.TwipsPerPixelX - .Left + 15
 
    ' links größer ziehen
    ElseIf mouBut = 1 And mouPos = 2 And _
      .MousePointer = 9 And .Width >= 500 Then
 
      .Left = P.X * Screen.TwipsPerPixelX - 15
      .Width = .Width + (oldLeft - .Left)
      oldLeft = .Left
 
    ' unten größer ziehen
    ElseIf mouBut = 1 And mouPos = 3 And _
      .MousePointer = 7 And .Height >= 500 Then
 
      .Height = P.Y * Screen.TwipsPerPixelY - .Top + 15
 
    ' oben größer ziehen
    ElseIf mouBut = 1 And mouPos = 4 And _
      .MousePointer = 7 And .Height >= 500 Then
 
      .Top = P.Y * Screen.TwipsPerPixelY - 15
      .Height = .Height + (oldTop - .Top)
      oldTop = .Top
    End If
  End With
End Sub

Dieser Tipp wurde bereits 11.100 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel