vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
vb@rchiv Offline-Reader - exklusiv auf der vb@rchiv CD Vol.4  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2018
 
zurück
Rubrik: Variablen/Strings · Array/ArrayList   |   VB-Versionen: VB200818.01.10
IndexOf für mehrdimensionale Arrays

Die generische Funktion "IndexOf" ermittelt das erste Auftreten eines bestimmten Wertes in einem n-dimensionalen Array

Autor:   Manfred BohnBewertung:     [ Jetzt bewerten ]Views:  11.282 
ohne HomepageSystem:  Win2k, WinXP, Vista, Win7, Win8, Win10kein Beispielprojekt 

Die generische Funktion "IndexOf" ermittelt das erste Auftreten eines bestimmten Wertes in einem n-dimensionalen Array.

Der Begriff "Wert" ist hier allgemein zu verstehen; es kann sich auch um einen Referenztyp handeln. Er muss aber dem Datentyp der Array-Deklaration entsprechen und die generische Schnittstelle IEquatable(Of T) muss implementiert sein.

Falls das Array nicht deklariert ist oder ein falscher Datentyp gesucht wird, gibt die Funktion Nothing zurück, sonst ein Integer-Array der Länge ArrayRank mit den Array-Indices des gesuchten Wertes.

Falls der gesuchte Wert im Array nicht enthalten ist, wird ein Array mit -1-Elementen zurückgegeben.

Die Suche durchläuft zunächst den ersten Index, dann die höheren Indices, d.h. ein Element am Index 1,2,3,4 eines vierdimensionalen Array liegt vor dem Element 4,3,2,1.

Der generische Parameter muss beim Aufruf der Funktion nicht angegeben werden. Er wird automatisch über den Datentyp des Parameters "ValueToFind" inferriert.

Die Funktion ermöglicht die Verwendung von "Option Strict On".

Beispiel:

Dim rndm As New System.Random(1234)
Dim bt16(15) As Byte
rndm.NextBytes(bt16)
Dim gd As New System.Guid(bt16)
 
Dim darr(10, 20, 30) As System.Guid
Dim inds() As Integer
 
darr(4, 5, 6) = gd : darr(6, 5, 4) = gd
inds = IndexOf(darr, gd) ' inds = 4,5,6
Public Function IndexOf(Of T As System.IEquatable(Of T)) _
  (ByVal arr As System.Array, ByVal ValueToFind As T) As Integer()
 
  If arr Is Nothing Then Return Nothing
  If ValueToFind Is Nothing Then Return Nothing
 
  Dim r As Integer = arr.Rank
  Dim i, k, ind1 As Integer
  Dim ind(r - 1) As Integer, fak(r - 1) As Integer
 
  ' 1D-Index des ersten gesuchten Wertes ermitteln
  Dim found As Boolean = False
  Try
    For Each el As T In arr
      If el.Equals(ValueToFind) Then found = True : Exit For
      ind1 += 1
    Next el
  Catch
    ' Inkompatibler Datentyp Array-Element <> ValueToFind
    Return Nothing
  End Try
 
  If Not found Then
    ' Der Wert ist nicht enthalten
    For i = 0 To r - 1 : ind(i) = -1 : Next i
    Return ind
  End If
 
  ' Hilfswerte für Indexrückrechnung bestimmen
  For i = 0 To r - 1
    fak(i) = 1
    For k = i + 1 To r - 1
      fak(i) *= (arr.GetUpperBound(k) + 1)
    Next k
  Next i
 
  ' N-Dimensionale Indices zu 1D-Index ermitteln
  For i = 0 To r - 1
    ind(i) = (ind1 - ind1 Mod fak(i)) \ fak(i)
    ind1 -= ind(i) * fak(i)
  Next i
 
  ' Rückgabe der Indices
  Return ind
End Function

Dieser Tipp wurde bereits 11.282 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2018 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel