Zeile und Spalte einer (Rich-)Textbox ermitteln Ermitteln der aktuellen Zeile und Spalte der Einfügemarke innerhalb einer (Rich-)Textbox.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  10.445
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Vista, Win7	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 17 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.1 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

In vielen Fällen wäre es schön, wenn eine Multiline-Textbox oder auch die RichTextbox entsprechende Eigenschaften für das Auslesen der aktuellen Zeilen- und Spaltenposition bereitstellen würden. Da es solche Eigenschaften aber nicht gibt, bedienen wir uns wieder einmal der Windows-API - wie soll's auch anders sein

' zunächst die benötigten API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Any) As Long
 
Private Const EM_LINEFROMCHAR = &HC9
Private Const EM_LINEINDEX = &HBB

' Zeilennummer der aktuellen Eingabeposition ermitteln
Public Function GetCurrentLine(hWnd As Long) As Long
  GetCurrentLine = SendMessage(hwnd, EM_LINEFROMCHAR, _
    -1, ByVal 0&) + 1
End Function

Ermitteln der aktuellen Spalte innerhalb der aktuellen Zeile

' Spaltennummer der aktuellen Zeile ermitteln
Public Function GetCurrentCol(TextBox As Control) As Long 
  GetCurrentCol = TextBox.SelStart - _
    SendMessage(TextBox.hWnd, EM_LINEINDEX, _
    GetCurrentLine(TextBox.hWnd) - 1, 0&) + 1
End Function

Beispiel...
Im nachfolgenden Beispiel wird bei jeder Positionsänderung des Eingabecursors die aktuelle Zeilen- und Spaltenposition in einem Labelfeld angezeigt. Plazieren Sie hierzu eine Textbox auf die Form und setzen die Eigenschaft Multiline auf True. Unterhalb der Textbox plazieren Sie dann noch ein LabelControl und benennen es lblPosition.

Die einzige Hürde, die es jetzt noch zu bewältigen gilt, ist das in Erfahrung bringen, wann sich die Eingabeposition überhaupt ändert. Die RichtextBox löst in diesem Fall ja immer das SelChange-Ereignis aus. Für die Standard-Textboxen gibt es dieses Ereignis aber nicht. Also setzen wir den Aufruf zum Anzeigen der Zeilen-/Spaltenposition in das KeyUp und zusätzlich noch in das MouseUp-Ereignis. Warum? Na ja, immer wenn eine Taste gedrückt wird, verändert sich bekanntlich auch die Eingabeposition. Die Eingabeposition kann aber auch durch gezieltes Klicken mit der Maus in irgendeinen Bereich der Textbox geändert werden - deswegen zusätzlich das MouseUp-Ereignis abfragen.

...bei Verwendung einer RichTextBox

Private Sub RichTextBox1_SelChange()
  lblPosition.Caption = "Zeile " & _
    GetCurrentLine(RichTextBox1.hWnd) & ", Spalte " & _
    GetCurrentCol(RichTextBox1)
End Sub

...bei Verwendung einer Standard-Textbox

Private Sub Text1_KeyUp(KeyCode As Integer, _
  Shift As Integer)
 
  lblPosition.Caption = "Zeile " & _
    GetCurrentLine(Text1.hWnd) & ", Spalte " & _
    GetCurrentCol(Text1)
End Sub
 
Private Sub Text1_MouseUp(Button As Integer, _
  Shift As Integer, X As Single, Y As Single)
 
  lblPosition.Caption = "Zeile " & _
    GetCurrentLine(Text1.hWnd) & ", Spalte " & _
    GetCurrentCol(Text1)
End Sub