Klassennamen ermitteln (Fremdprogramme beenden) Hier wird gezeigt, wie man den Klassennamen laufender Programme ermitteln kann.
Autor:   Heinz Prelle	Bewertung:     [ Jetzt bewerten ]	Views:  6.830
www.visual-basic5.de	System:  Win9x, WinNT, Win2000, WinXP, Vista	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 12 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.9 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Der nachfolgende Tipp ist eine Ergänzung zu einem früheren Tipp: Fremdanwendung beenden

In diesem Tipp wurde gezeigt, wie man eine beliebige Fremdanwendung über deren Klassennamen programmgesteuert beenden kann. Wie man nun den Klassennamen in Erfahrung bringt, das zeigt Ihnen der nachfolgende Tipp.

' zunächst die benötigten API-Deklarationen
Option Explicit
Private Declare Function WindowFromPoint Lib "user32" ( _
  ByVal xpoint As Long, _
  ByVal ypoint As Long) As Long
 
Private Declare Function GetClassName Lib "user32" _
  Alias "GetClassNameA" ( _
  ByVal hwnd As Long, _
  ByVal lpClass As String, _
  ByVal nMaxCount As Long) As Long
 
Private Declare Function GetCursorPos Lib "user32" ( _
  lpPoint As POINTAPI) As Long
 
Private Type POINTAPI
  x As Long
  y As Long
End Type
 
Private bStop           As Boolean
Private sClassName      As String
Private x               As Long
Private y               As Long
Private lRetVal         As Long
Private lPrevWnd        As Long
Private lActWnd         As Long
 
Private ptPoint As POINTAPI

Klassennamen ermitteln
Die nachfolgende Routine ermittelt den Klassennamen des Fensters/Objektes, über welches sich der Mauszeiger gerade befindet.

' Klassennamen ermitteln
Private Function fGetClassName()
  bStop = False
  lPrevWnd = 0
  Do
    If bStop = True Then Exit Do
    Call GetCursorPos(ptPoint)
    x = ptPoint.x
    y = ptPoint.y
    lActWnd = WindowFromPoint(x, y)
    If lActWnd <> lPrevWnd Then
      sClassName = String$(256, " ")
      lPrevWnd = lActWnd
      lRetVal = GetClassName(lActWnd, sClassName, 255)
      sClassName = Left$(sClassName, _
        InStr(sClassName, vbNullChar) - 1)
      Label1 = "Die Maus ist über [ " & _
        sClassName & " ]"
    End If
    DoEvents
  Loop
End Function

Ein paar Erläuterungen
Über die GetCursorPos-API wird die Position des Mauszeigers ermitteln (x- und y-Position in der Maßeinheit Pixel). Die API-Funktion WindowFromPoint ermittelt nun das Fensterhandle bzgl. der x- und y-Parameter der Mausposition und gibt dieses als Long-Wert zurück. Mit Hilfe des Fensterhandles kann man nun mittels der API-Funktion GetClassName den Klassennamen in Erfahrung bringen.

In einer der nächsten Tipps zeigen wir Ihnen dann noch, wie man die Handles der offenen Anwendungen nicht per "Maussteuerung", sondern gezielt per Programmcode ermitteln kann.