vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v3.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2018
 
zurück
Rubrik: Datenbanken · Sonstiges   |   VB-Versionen: VB629.08.12
MID-Funktion im SQL-Statement

Dieser Code zeigt, wie man innerhalb einer SQL-Abfrage die bekannte MID-Funktion verwenden kann - sowohl für Access-Datenbanken, als auch MS SQL Server Datenbanken.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  5.234 
www.tools4vb.deSystem:  WinXP, Vista, Win7, Win8, Win10kein Beispielprojekt 

Und noch einmal zum Thema SQL-Abfragen mit integrierten Berechnungsfunktionen. Heute erweiter wir die universelle Funktion dbSQLFunc aus unserem vorigen Tipp um den Mid-Parameter, mit dem sich eine Teil-Zeichenkette für einen Abfragevergleich oder auch eine Ausgabe erstellen lässt.

' VBA-Funktionen / SQL-Funktionen
Public Function dbSQLFunc(ByVal sFunc As String, ParamArray vExpr() As Variant) As String
  Select Case UCase$(sFunc)
    ' IIf(...,...,...) Funktion
    Case "IIF"
      If DbSystem = dbMSAccess Then
        dbSQLFunc = "IIf(" & vExpr(0) & "," & vExpr(1) & "," & vExpr(2) & ")"
      Else
        dbSQLFunc = "CASE WHEN " & vExpr(0) & " THEN " & vExpr(1) & " ELSE " & vExpr(2) & " END"
      End If
 
    ' DateDiff-Funktion
    ' Erwartet wird ein Feldname oder ein Datum im Format dd.mm.yyyy
    Case "DATEDIFF"
      Dim vDate1 As String
      Dim vDate2 As String
 
      If DbSystem = dbMSAccess Then
        vDate1 = vExpr(1)
        vDate2 = vExpr(2)
        If (InStr(vDate1, "-") Or InStr(vDate1, ".")) And _
         (InStr(vDate1, "[") = 0) And (Left$(vDate1, 3) <> "tbl") Then
         vDate1 = "#" & Format$(CDate(vDate1), "mm-dd-yyyy") & "#"
        End If
        If (InStr(vDate2, "-") Or InStr(vDate2, ".")) And _
          (InStr(vDate2, "[") = 0) And (Left$(vDate2, 3) <> "tbl") Then
          vDate2 = "#" & Format$(CDate(vDate2), "mm-dd-yyyy") & "#"
        End If
 
        dbSQLFunc = "DATEDIFF('" & vExpr(0) & "'," & ReplaceEx(vDate2, "[", "]", "") & "," & _
          ReplaceEx(vDate1, "[", "]", "") & ")"
      Else
        vDate1 = vExpr(1)
        vDate2 = vExpr(2)
        If (InStr(vDate1, "-") Or InStr(vDate1, ".")) And _
          (InStr(vDate1, "[") = 0) And (Left$(vDate1, 3) <> "tbl") Then 
          vDate1 = "'" & Format$(CDate(vDate1), "dd.mm.yyyy") & "'"
        End If
        If (InStr(vDate2, "-") Or InStr(vDate2, ".")) And _
          (InStr(vDate2, "[") = 0) And (Left$(vDate2, 3) <> "tbl") Then 
          vDate2 = "'" & Format$(CDate(vDate2), "dd.mm.yyyy") & "'"
        End If
 
        dbSQLFunc = "DATEDIFF(" & vExpr(0) & "," & ReplaceEx(vDate2, "[", "]", "") & "," & _
          ReplaceEx(vDate1, "[", "]", "") & ")"
      End If
 
    ' Mid(...) Funktion
    Case "MID"
      If DbSystem = dbMSAccess Then
        dbSQLFunc = "Mid(" & vExpr(0) & "," & CStr(vExpr(1)) & "," & CStr(vExpr(2)) & ")"
      Else
        dbSQLFunc = "SUBSTRING(" & vExpr(0) & "," & CStr(vExpr(1)) & "," & CStr(vExpr(2)) & ")"
      End If
 
  End Select
End Function

Je nach verwendetem Datenbanksystem (Access oder SQL-Server) generiert die Funktion dbSQLFunc die korrekte SQL-Syntax.

Beispiel:

' Nur das erste Zeichen eines Feldes selektieren
sSQL = "SELECT " & dbSQLFunc("MID", "KdName", 1, 1) & " FROM ..."

Dieser Tipp wurde bereits 5.234 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2018 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel