vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v3.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Controls   |   VB-Versionen: VB2005, VB2008, VB2010, VB201218.12.13
Individualisierte Standard-Groupbox

Wie man mit 4 neuen Eigenschaften und nur einer Funktion die Standard-GroupBox ein wenig umgestalten kann.

Autor:   Dietrich HerrmannBewertung:     [ Jetzt bewerten ]Views:  7.204 
ohne HomepageSystem:  Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Für diejenigen, die mit VB.NET beginnen veranschaulicht folgender Code recht einfach, wie man ein Standard-Control im eigenen Sinne umgestalten kann. Ich zeige dazu eine Klasse.

Diesen Code als Klasse dem Projekt hinzufügen und dann das Projekt erstellen. Danach steht die "neue" Groupbox zur Verfügung und die neuen Eigenschaften können eingestellt werden.

Hier die Klasse:

Imports System.Drawing, System.Drawing.Drawing2D, System.Drawing.Text
 
Public Class CustomGroupBox
  Inherits GroupBox
 
  Private _bordercolor As Color
  Private _borderwidth As Short
  Private _borderstyle As ButtonBorderStyle
  Private _textalign As StringAlignment
 
  Public Sub New()
    MyBase.New()
    ' Standardwerte vorgeben
    Me._bordercolor = Color.Black
    Me._borderwidth = 1
    Me._borderstyle = ButtonBorderStyle.Solid
    Me._textalign = StringAlignment.Near
  End Sub
 
#Region " Properties "
  Public Property BorderColor() As Color
    Get
      Return Me._bordercolor
    End Get
    Set(ByVal value As Color)
      Me._bordercolor = value
    End Set
  End Property
 
  Public Property BorderWidth() As Short
    Get
      Return Me._borderwidth
    End Get
    Set(ByVal value As Short)
      Me._borderwidth = value
    End Set
  End Property
 
  Public Property BorderStyle() As ButtonBorderStyle
    Get
      Return Me._borderstyle
    End Get
    Set(ByVal value As ButtonBorderStyle)
      Me._borderstyle = value
    End Set
  End Property
 
  Public Property TextAlign() As StringAlignment
    Get
      Return Me._textalign
    End Get
    Set(ByVal value As StringAlignment)
      Me._textalign = value
    End Set
  End Property
#End Region
 
  ' Groupbox neu zeichnen
  Protected Overrides Sub OnPaint(ByVal e As PaintEventArgs)
    With Me
      ' Textgröße ermitteln
      Dim sz As Size = TextRenderer.MeasureText(.Text, .Font)
      Dim rect As Rectangle = .ClientRectangle()
      With rect  ' das Rechteck der Box
        .Height = CType(.Height - (sz.Height / 2), Integer)
        .Y = CType(.Y + (sz.Height / 2), Integer)
        'Border zeichnen
        ControlPaint.DrawBorder(e.Graphics, rect, _
          _bordercolor, _borderwidth, _borderstyle, _
          _bordercolor, _borderwidth, _borderstyle, _
          _bordercolor, _borderwidth, _borderstyle, _
          _bordercolor, _borderwidth, _borderstyle)
        ' Text zeichnen gemäß dem Alignment
        Dim TextPosition As Rectangle = Me.ClientRectangle()
        With TextPosition
          .Width = sz.Width
          .Height = sz.Height
          Select Case _textalign
            Case StringAlignment.Near
              .X = .X + _borderwidth * 2
            Case StringAlignment.Center
              .X = (Me.ClientRectangle.Width - sz.Width) / 2
            Case StringAlignment.Far
              .X = Me.ClientRectangle.Right - .Width - _borderwidth * 2
          End Select
          With e.Graphics
            .SmoothingMode = SmoothingMode.HighQuality
            .TextRenderingHint = TextRenderingHint.ClearTypeGridFit
            .FillRectangle(New SolidBrush(Me.BackColor), TextPosition)  'Hintergrund des Texts
            .DrawString(Me.Text, Me.Font, New SolidBrush(Me.ForeColor), TextPosition)
          End With
        End With
      End With
    End With
  End Sub
 
End Class

Dieser Tipp wurde bereits 7.204 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel