vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Dateisystem · Dateien allgemein   |   VB-Versionen: VB4, VB5, VB613.09.01
Alle Dateien/Ordner eines Ordners löschen

Das Windows-API stellt eine kleine aber feine Funktion zur Verfügung, um alle Dateien eines Ordners (inkl. Unterordner) zu löschen.

Autor:   Thomas BannertBewertung:     [ Jetzt bewerten ]Views:  57.362 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Vom Windows-Explorer ist man es gewohnt, dass:

  1. Dateien nicht sofort dauerhaft gelöscht werden, sondern zunächst in den Windows-Papierkorb verschoben werden
  2. ganze Ordner inkl. aller darin enthaltenen Unterordner und Dateien mit einem Tastendruck gelöscht werden können
  3. während des Löschvorgangs eine Fortschrittsanzeige eingblendet wird

Um solch eine Funktion in der eigenen Anwendung zu integrieren, stellt uns das Windows-API die Funktion SHFileOperation zur Verfügung. Über die Flags-Eigenschaft der der Funktion zu übergebenden Struktur lassen sich einige interessante Einstellungen festlegen, wie z.B. Löschen in den Papierkorb, Löschen mit zusätzlicher Löschbestätigung usw.

Nachfolgend stellen wir Ihnen die universelle Funktion SHDelete vor, über welche Sie u.a. auch den Inhalt eines gesamten Ordner löschen können, mit der Möglichkeit alle relevanten Daten bequem als Parameter angeben zu können.

Die Funktion löscht den übergebenen Datei- oder Verzeichnisamen bzw. ein übergebenes Array mit Datei- oder Verzeichnisnamen. Sicherheitshalber haben wir den optionalen Parameter bAllowUndo standardmäßig auf True gesetzt.

Die Funktion selbst gibt meist True zurück. Nur wenn der Befehl...

SHDelete = Not CBool(SHFileOperation(oFileOP))

...einen echten Fehler hat wird False zurückgegeben. AbortFiles enthält den Status, ob der Benutzer den Löschvorgang aufgrund nicht löschbarer Dateien abgebrochen hat (True).

Kopieren Sie den nachfolgenden Code in ein Modul:

' API Deklarationen
Private Type SHFILEOPSTRUCT
  hWnd      As Long
  wFunc     As Long
  pFrom     As String
  pTo       As String
  fFlags    As Integer
  fAnyOperationsAborted As Long
  hNameMappings     As Long
  lpszProgressTitle As String
End Type
 
Private Declare Function SHFileOperation Lib "Shell32.dll" _
  Alias "SHFileOperationA" ( _
  lpFileOp As SHFILEOPSTRUCT) As Long
 
Private Const FO_DELETE = &H3
Private Const FOF_ALLOWUNDO = &H40
Private Const FOF_SILENT = &H4
Private Const FOF_NOCONFIRMATION = &H10
Private Const FOF_SIMPLEPROGRESS = &H100
Private Const FOF_NOERRORUI = &H400
 
 
' Löschen aller Dateien/Ordner eines Unterordners
' 
' Parameterbeschreibung:
' ======================
' vFiles        - Ein Array oder String, der die zu löschende
'                 Datei oder das Verzeichnis angibt.
' lStartHwnd    - Handle des aufrufenden Fensters
' bConfirmation - Soll der Benutzer die Aktion bestätigen?
' bShowProgress - Soll ein Fortschritt angezeigt werden?
' bShowNames    - Sollen auch die Namen angezeigt werden?
' bAllowUndo    - Soll in den Papierkorb gelöscht werden?
' bShowErrors   - Sollen Fehler angezeigt werden?
' AbortFiles    - Rückgabe, ob Benutzerabbruch
Public Function SHDelete(vFiles As Variant, _
  Optional lStartHwnd As Long, _
  Optional bConfirmation As Boolean, _
  Optional bShowProgress As Boolean, _
  Optional bShowNames As Boolean, _
  Optional bAllowUndo As Boolean = True, _
  Optional bShowErrors As Boolean = True, _
  Optional bAbortFiles As Boolean) As Boolean
 
  Dim i             As Long
  Dim oFileOP       As SHFILEOPSTRUCT
 
  With oFileOP    
    ' Das Handle des aufrufenden Fensters
    .hWnd = lStartHwnd
 
    ' Das From setzten
    If IsArray(vFiles) Then
      ' Array auseinandernehmen
      For i = LBound(vFiles) To UBound(vFiles)
        .pFrom = .pFrom & vFiles(i) & vbNullChar
      Next i
      .pFrom = .pFrom & vbNullChar
    ElseIf VarType(vFiles) = vbString Then
      ' Wenn ein Verzeichnis dann aber ohne
      ' abschließendes "\"-Zeichen
      If Right(vFiles, 1) = "\" Then _
        vFiles = Left(vFiles, Len(vFiles) - 1)
 
      ' Prüfen, ob mit 2 vbNullChars abgeschlossen
      .pFrom = vFiles
      While Right$(.pFrom, 2) <> String$(2, vbNullChar)
        .pFrom = .pFrom & vbNullChar
      Wend
    End If
 
    ' Flags setzten
    If bAllowUndo Then .fFlags = FOF_ALLOWUNDO
    If Not bShowProgress Then .fFlags = .fFlags Or _
      FOF_SILENT
    If Not bConfirmation Then .fFlags = .fFlags Or _
      FOF_NOCONFIRMATION
    If Not bShowNames Then .fFlags = .fFlags Or _
      FOF_SIMPLEPROGRESS
    If Not bShowErrors Then .fFlags = .fFlags Or _
      FOF_NOERRORUI
 
    ' wir wollen löschen
    .wFunc = FO_DELETE
 
    ' Und gib ihm ;-) !
    SHDelete = Not CBool(SHFileOperation(oFileOP))
    If Not IsMissing(bAbortFiles) Then
      ' Sollte der Benutzer abgebrochen, haben evtl.
      ' eine Info an die aufrufende Funktion.
      bAbortFiles = CBool(.fAnyOperationsAborted)
    End If
  End With
End Function

Beispiel
Nachfolgend ein Beispiel, welches den Ordner TEMP mit alle seinen Unterordnern und Dateien auf dem Laufwerk C:\ löscht, d.h. nicht sofort löscht, sondern in den Windows-Papierkorb - und zwar erst nach einer zusätzlichen Sicherheitsabfrage. Desweiteren wird während des Löschvorgangs eine Fortschittsanzeige eingeblendet.

' "C:\TEMP" löschen
SHDelete "C:\TEMP", Me.hWnd, True, True, True

...und noch ein Beispiel...
Im nachfolgenden Beispiel werden drei ganz bestimmte Dateien gelöscht, welche als Array an die Funktion übergeben werden:

' 3 Dateien löschen
Dim vFiles(2) As String
 
vFiles(0) = "c:\temp\file1.tmp"
vFiles(1) = "c:\temp\file2.tmp"
vFiles(2) = "c:\temp\file3.tmp"
 
If SHDelete(vFiles(), Me.hWnd, True, True, True) Then
  MsgBox "Löschvorgang erfolgreich!"
Else
  MsgBox "Fehler beim Löschen!"
End If

Dieser Tipp wurde bereits 57.362 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Aktuelle Diskussion anzeigen (1 Beitrag)

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel