vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Controls · ListView   |   VB-Versionen: VB4, VB5, VB611.01.02
ListView-Inhalt speichern und laden

Zwei Funktionen für Ihre Projekte, mit denen sich die Inhalte von ListView-Steuerelementen einfach laden und speichern lassen.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  30.749 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Das ListView-Control - ein Steuerelement, welches aufgrund seiner vielfältigen Einsatzmöglichkeit sehr häufig in den eigenen Projekten verwendet wird (ich glaub', ich wiederhole mich da immer wieder - aber es ist halt so - bietet so einiges, doch leider fehlen meiner Meinung nach zwei sehr wichtige Funktionen:

a) Speichern des gesamten Daten-Inhaltes
b) Einlesen und Anzeigen gespeicherter Daten

Und weil wir ja alle Visual Basic Programmierer sind, proggen wir uns eben diese beiden Funktionen eben selbst

Speichern der ListView-Daten
Besteht die Liste aus nur einer Datenspalte, könnte man ja einfach die Liste durchlaufen und die einzelnen Texte zeilenweise in eine Datei speichern. Was aber, wenn pro Zeile mehrere Spalten-Inhalte zu speichern sind? Dann speichern wir die Datenzeilen dennoch zeilenweise, wobei die einzelnen Spalten durch ein bestimmtes Zeichen voneinander getrennt werden. Hierzu eignet sich das Tabulator-Zeichen, da es sich hierbei um ein Zeichen handelt, welches innerhalb der Liste (Daten) wohl kaum verwendet wird. Zusätzlich zu den Daten soll aber auch ein evtl. festgelegter Key-Wert gespeichert werden - auch kein Problem, packen wir einfach vorne dran

' ListView: Inhalt in eine Datei speichern
Public Sub lvw_WriteData(lvw As ListView, _
  sDataFile As String)
 
  Dim F As Integer
  Dim intCols As Integer
  Dim I As Integer
  Dim U As Integer
 
  ' Datei öffnen (ggf. überschreiben)
  F = FreeFile
  Open sDataFile For Output As #F
 
  ' Anzahl Spalten im ListView
  intCols = lvw.ColumnHeaders.Count
 
  ' ListView zeilenweise speichern
  With lvw.ListItems
    For I = 1 To .Count
      With lvw.ListItems(I)
        ' als erstes wird der Key-Wert gespeichert
        Print #F, .Key; vbTab;
 
        ' dann wird der Text der 1. Spalte gespeichert
        Print #F, .Text;
 
        ' Jetzt alle weiteren Spalten-Inhalte
        For U = 1 To intCols - 1
          Print #F, vbTab; .SubItems(U);
        Next U
 
        ' Zeilenvorschub
        Print #F, ""
      End With
    Next I
  End With
 
  ' Datei schliessen
  Close #F
End Sub

Einlesen und Anzeigen gespeicherter Daten
Bei der "Lese-Funktion" gibt es eigentlich nichts besonderes zu beachten. Der obige Code muss nur entsprechend für das Auslesen der Datei umgesetzt werden. Einem möglichen Laufzeitfehler möchten wir aber dennoch vorbeugen: Es würde ein Laufzeitfehler ausgelöst werden, wenn versucht wird, mehr Spalten-Daten anzuzeigen, alse das ListView selbst Spalten besitzt.

' ListView: Inhalt aus Datei einlesen und anzeigen
' bAppend gibt an, ob der Inhalt angefügt (True)
' oder das ListView vorher gelöscht werden soll (False)
Public Sub lvw_ReadData(lvw As ListView, _
  ByVal sDataFile As String, _
  Optional ByVal bAppend As Boolean = False)
 
  Dim F As Integer
  Dim sLine As String
  Dim sItem() As String
  Dim intCols As Integer
  Dim I As Integer
  Dim itemX As ListItem
 
  ' ListView löschen (falls bAppend = False)
  If Not bAppend Then lvw.ListItems.Clear
 
  ' Existiert die Datei überhaupt?
  If Dir(sDataFile, vbNormal) <> "" Then
    ' Anzahl Spalten im ListView
    intCols = lvw.ColumnHeaders.Count
 
    ' Datei zum Lesen öffnen
    F = FreeFile
    Open sDataFile For Input As #F
 
    ' Inhalt zeilenweise auslesen
    With lvw.ListItems
      While Not EOF(F)
        Line Input #F, sLine
 
        ' Zeile in die einzelnen Spalten zerlegen
        sItem = Split(sLine, vbTab)
 
        ' Falls die Anzahl Datenspalten nicht mit der
        ' Anzahl Spalten im ListView übereinstimmen,
        ' -> Array "zurechtrücken"
        If UBound(sItem) <> intCols Then
          ReDim Preserve sItem(intCols)
        End If
 
        ' 1. Eintrag (sItem(0)) enthält den Key-Wert
        Set itemX = .Add(, sItem(0), sItem(1))
 
        ' Jetzt aller "SubItems"-Daten hinzufügen
        For I = 2 To intCols
          itemX.SubItems(I - 1) = sItem(I)
        Next I
      Wend
    End With
 
    ' Datei schliessen
    Close #F
  End If
End Sub

Anwendungsbeispiel
Beim Laden der Form soll eine evtl. vorhandene ListView-Datendatei eingelesen werden:

Private Sub Form_Load()
  ' ListView-Daten lesen
  lvw_ReadData ListView1, App.Path & "\Adressen.dat"
End Sub

Beim Beenden der Form wird dann der aktuelle Inhalt des ListView-Controls gespeichert:

Private Sub Form_Unload(Cancel As Integer)
  ' ListView-Daten speichern
  lvw_WriteData ListView, App.Path & "\Adressen.dat"
End Sub

Ach ja, noch etwas. Am besten Sie fügen die beiden "neuen" Funktionen in ein Modul Ihres Projekts ein, da Sie dann jederzeit Zugriff auf die beiden Funktionen haben, egal welche Form gerade aktiv ist. Es soll ja vorkommen, dass eine Anwendung mehrere ListView-Controls enthält