vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v3.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: HTML/Internet/Netzwerk · Sonstiges   |   VB-Versionen: VB4, VB5, VB616.07.03
Programm-Aktualität online prüfen 2

Prüft anhand einer Onlinedatei die Version und gibt als Ergebnis zurück, ob eine neuere Version verfügbar ist.

Autor:   Sascha KurthBewertung:     [ Jetzt bewerten ]Views:  18.232 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Angenommen Sie stellen auf Ihrem Webserver immer die aktuellste Version Ihrer Anwendung zum Download bereit und möchten nun über eine kleine Funktion innerhalb der Anwendung prüfen, ob der Anwender bereits die neueste Version verwendet oder ob eine neuere Version zum Download bereitsteht.

Wie könnte man hier vorgehen?
Eine von sicherlich zahlreichen Möglichkeiten möchten wir Ihnen heute vorstellen.

Das Prinzip ist recht einfach. Auf dem Webserver speichern Sie eine Datei, deren Dateiname der ProductName-Eigenschaft des App-Objekt entspricht. Als Extension verwenden wir .version. Die Datei selbst beinhaltet auch nur eine einzige Textzeile - und zwar die aktuelle Versionsnummer.

Beispiel:
In den Projekt-Eigenschaften haben Sie als "Produktname" unter "Versionsinformationen" MyProgram festgelegt. Die aktuelle Download-Version ist 1.02. Auf dem Webserver muss sich nun folgende Datei befinden:

myprogram.version
1.02

Nun braucht man lediglich die besagte .version-Datei vom Server auszulesen und mit der aktuell verwendeten Version zu vergleichen.

Für die Übertragung des Datei-Inhaltes verwenden wir das Microsoft Internet-Transfer Control (MSINET). Dieses platzieren Sie auf die Form und rufen dann folgende Funktion auf:

' WICHTIG:
' Die Konstante URL beinhaltet NUR den Ordner nicht die Datei
' Der ProductName muss in den Projekteigenschaften angegeben werden
' Die Onlinedatei muss Produktname + ".version" heißen und beinhaltet
' jediglich die Versionsnummer in der Form #.## (z.B: 1.0 oder 1.02 oder 2.3)
 
' Konstante URL zum Dateiverzeichnis
Const sURL = "http://www.ihredomain.de/ihrdateiverzeichnis/"
' Die Funktion isCurrentVersion gibt 1 zurück,
' wenn das Programm auf dem neusten Stand ist,
' 0 wenn dieses veraltet ist oder 2 wenn ein
' Fehler aufgetreten ist
Public Function isCurrentVersion() As Integer
  Dim sVersion As String ' komplette Versionsnummer
  Dim nMajor As Long     ' Hauptversionsnummer
  Dim nMinor As Long     ' Subversionsnummer
 
  ' Konfigurieren des Inet-Controls
  With Inet1
    .AccessType = icDirect ' Direkte Verbindung
    .Protocol = icHTTP     ' HTTP-Protokoll verwenden
 
    ' Inhalt der Versionsdatei in Varibale speichern!
    sVersion = .OpenURL(sURL & LCase$(App.ProductName) & ".version", _
      icString)
 
    If Len(sVersion) > 50 Or Len(sVersion) = 0 Then
      ' Fehler! Evtl. konnte die Datei auf dem Server
      ' nicht gefunden werden!
      isCurrentVersion = 2
    Else
      ' Ggf. abschließenden Zeilenumbruch entfernen
      If InStr(sVersion, Chr$(13)) > 0 Then _
        sVersion = Left$(sVersion, InStr(sVersion, Chr$(13)) - 1)
 
      ' Versionsteile extrahieren
      nMajor = Val(Left$(sVersion, InStr(sVersion, ".") - 1))
      nMinor = Val(Mid$(sVersion, InStr(sVersion, ".") + 1))
 
      ' Prüfen!
      isCurrentVersion = IIf((App.Major < nMajor) Or _
        (App.Major = nMajor And App.Minor < nMinor), 0, 1)
    End If
  End With
End Function

Als Rückgabe erhält man nun entweder 1, falls man bereits die aktuelle Version verwendet, 0, falls eine neuere Version zum Download bereitsteht oder aber 2, falls ein Fehler aufgetreten ist.
 

Damit Sie das ganze einmal online testen können, haben wir Ihnen eine "Versions-Info"-Datei auf unseren Server bereitgestellt: http://www.vbarchiv.de/test/myprogram.version

Erstellen Sie ein neues Projekt und legen unter Projekt - Eigenschaften... im Register Erstellen unter Versionsinformationen als Produktname MyProgram fest. Setzen Sie die Programmversion im Dialog für den ersten Test auf Major = 1 und Minor = 0.

Fügen Sie nun das "Microsoft Internet-Transfer Control" auf die Form1 und zusätzlich noch einen CommandButton.

Fügen Sie obigen Code vollständig in den Codeteil der Form ein und ändern die URL (Konstante sURL) wie folgt:

' Konstante URL zum Dateiverzeichnis
Const sURL = "http://www.vbarchiv.de/test/"

Beim Klick auf den CommandButton erfolgt die Onlineprüfung und Sie sollten die Meldung erhalten, dass eine neuere Version zum Download bereitsteht.

Private Sub Command1_Click()
  Dim nResult As Integer
 
  nResult = isCurrentVersion()
  If nResult = 1 Then
    MsgBox "Sie arbeiten bereits mit der neuesten Version."
  ElseIf nResult = 2 Then
    MsgBox "Fehler!"
  Else
    MsgBox "Es steht eine neuere Version zum Download bereit."
  End If
End Sub

Beenden Sie das Testprogramm und setzen nun die Versionsnummer auf 1.2 (Major = 1, Minor = 2). Starten Sie das Projekt erneut und klicken wiederum auf den CommandButton. Jetzt sollte die Meldung erscheinen, dass Sie bereits mit der neuesten Version arbeiten.

Hinweis:
Da viele Webserver bei Dateinamen zwischen Groß- und Kleinschreibung unterscheiden, sollten Sie die .version-Datei immer in Kleinschreibung hochladen.
 

Dieser Tipp wurde bereits 18.232 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel