vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Zippen wie die Profis!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2014
 
zurück
Rubrik: Grafik und Font · Grafische Effekte   |   VB-Versionen: VB5, VB604.02.04
Bild in Graustufen umwandeln

Dieser Tipp zeigt, wie sich ein Farbbild in Graustufen umwandeln l?sst.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  12.943 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8 Beispielprojekt auf CD 

Manchmal ist es notwendig ein Farbbild in Graustufen umzuwandeln. Das Ganze ist auch gar nicht schwer, wie nachfolgender Tipp zeigt. Auf Wunsch lässt sich sogar eine transparente Farbe bestimmen, die bei der Umwandlung dann unberücksichtigt bleibt.

Erstellen Sie ein neues Projekt, platzieren auf die Form eine PictureBox und einen Command-Button. Laden Sie ein beliebiges Bild in die PictureBox und setzen die Eigenschaft BorderStyle = 0 und AutoSize = True. Fügen Sie jetzt noch nachfolgenden Code ein und starten das Projekt.

Private Sub Command1_Click()
  DoGrayScale Picture1
End Sub
Private Sub DoGrayScale(picSource As PictureBox, _
  Optional ByVal nTransColor As Long = -1)
 
  ' Farbbild in Graustufen umwandeln
  Dim nHeight As Long
  Dim nWidth As Long
  Dim x As Long
  Dim y As Long
  Dim nColor As Long
  Dim nRed As Long
  Dim nGreen As Long
  Dim nBlue As Long
  Dim nGray As Long
  Dim nScaleMode As Long
 
  With picSource
    ' Scalemode auf Pixel setzen
    nScaleMode = .ScaleMode
    .ScaleMode = vbPixels
 
    ' Größe der PictureBox in Pixel
    nWidth = .ScaleWidth
    nHeight = .ScaleHeight
 
    ' alle Pixel in x- und y-Richtung ermitteln
    ' und in den entsprechenden Grauton umwandeln
    For x = 0 To nWidth - 1
      For y = 0 To nHeight - 1
        ' aktueller Farbwert
        nColor = .Point(x, y)
 
        ' Farbwert nur umwandeln, wenn es sich NICHT
        ' um die transparente Farbe handelt
        If nColor <> nTransColor Then
          ' Farbwert nach RGB-Wert umwandeln
          nRed = nColor Mod 256
          nGreen = ((nColor And &HFF00) / 256&) Mod 256&
          nBlue = (nColor And &HFF0000) / 65536
 
          ' Farbwert in Grauton umwandeln
          nGray = ((nRed * 30) + (nGreen * 60) + (nBlue * 10)) / 100
          If nGray > 255 Then nGray = 255
 
          ' aktuellen Farbwert ersetzen
          picSource.PSet (x, y), RGB(nGray, nGray, nGray)
        End If
      Next y
    Next x
 
    ' Scalemode wieder auf den ursprünglichen Wert zurücksetzen
    .ScaleMode = nScaleMode
  End With
End Sub

Soll bei der Umwandlung des Farbbildes ein bestimmter Farbwert unberücksichtigt bleiben (z.B. bei transparenten GIFs), geben Sie beim Aufruf der DoGrayScale-Prozedur die transparente Farbe als zusätzlichen 2. Parameter an:

' transparente-Farbe: weiß
DoGrayScale Picture1, vbWhite

Oder...

' transparente Farbe = Farbwert links-oben
DoGrayScale Picture1, Picture1.Point(0, 0)

Dieser Tipp wurde bereits 12.943 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Aktuelle Diskussion anzeigen (2 Beiträge)

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2014 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel