GetDriveType-Funktion Diese Funktion ermittelt zu einem angegebenen Laufwerksbuchstaben den Laufwerkstyp.
Betriebssystem:  Win95, Win98, WinNT 3.1, Win2000, WinME	Views:  15.292

Deklaration:

Declare Function GetDriveType Lib "kernel32.dll" _
  Alias "GetDriveTypeA" ( _
  ByVal nDrive As String) As Long

Beschreibung:
Diese Funktion ermittelt zu einem angegebenen Laufwerksbuchstaben den Laufwerkstyp.

Parameter:

nDrive

Erwartet einen String, der den Laufwerksbuchstaben des zu ermittelnden Laufwerkstyps angibt.

Rückgabewert:
Die Rückgabe ist eine der nachfolgend aufgeführten Rückgabe-Konstanten oder "1" wenn das angegebene Laufwerk nicht existiert.

' CD-Rom Laufwerk
Const DRIVE_CDROM = 5
 
' Festplatte
Const DRIVE_FIXED = 3
 
' RAM-Laufwerk
Const DRIVE_RAMDISK = 6
 
' Netz-Laufwerk
Const DRIVE_REMOTE = 4
 
' Diskettenlaufwerk/Wechseldatenträger (z.B. auch ZIP)
Const DRIVE_REMOVABLE = 2

Beispiel:

Private Declare Function GetDriveType Lib "kernel32.dll" _
  Alias "GetDriveTypeA" ( _
  ByVal nDrive As String) As Long
 
Private Const DRIVE_CDROM = 5
Private Const DRIVE_FIXED = 3
Private Const DRIVE_RAMDISK = 6
Private Const DRIVE_REMOTE = 4
Private Const DRIVE_REMOVABLE = 2

Private Sub Command1_Click()
  Dim ChkDrive As String
 
  ChkDrive = InputBox("Bitte geben sie einen Laufwerksbuchstaben ein", _
    "Lauferkstyp ermitteln", "c:\")
 
  Select Case GetDriveType(ChkDrive)
    Case DRIVE_CDROM
      MsgBox "Das angegebene Laufwerk ist ein CD-ROM Laufwerk", vbInformation +  _
        vbOKOnly, "Laufwerkstyp"
    Case DRIVE_FIXED
      MsgBox "Das angegebene Laufwerk ist eine Festplatte", vbInformation +  _
        vbOKOnly, "Laufwerkstyp"
    Case DRIVE_RAMDISK
      MsgBox "Das angegebene Laufwerk ist ein RAM-Laufwerk", vbInformation +  _
        vbOKOnly, "Laufwerkstyp"
    Case DRIVE_REMOTE
      MsgBox "Das angegebene Laufwerk ist ein Netzwerk-Laufwerk", vbInformation + _
        vbOKOnly, "Laufwerkstyp"
    Case DRIVE_REMOVABLE
      MsgBox "Das angegebene Laufwerk ist ein Diskettenlaufwerk", vbInformation + _
        vbOKOnly, "Laufwerkstyp"
    Case Else
      MsgBox "Das angegebene Laufwerk existiert nicht", vbInformation +  _
        vbOKOnly, "Laufwerkstyp"
  End Select
End Sub