Public Class TboxCtrl
    Inherits TextBox
 
#Region "Api-Deklarationen"
    Private Const WM_PAINT As Integer = &HF%
 
    Private Declare Function ReleaseDC Lib "user32" ( _
        ByVal hwnd As IntPtr, _
        ByVal hdc As IntPtr) As Int32
 
    Private Declare Function GetDC Lib "user32" ( _
         ByVal hwnd As IntPtr) As IntPtr
 
#End Region
 
    Private myBorderCol As System.Drawing.Color = Color.Black
 
#Region "Konstruktor"
    Public Sub New()
        MyBase.New()
        MyBase.BorderStyle = BorderStyle.FixedSingle
    End Sub
#End Region
 
#Region "Properties"
 
    Public Property BorderColor() As System.Drawing.Color
        Get
            Return myBorderCol
        End Get
        Set(ByVal Value As System.Drawing.Color)
            myBorderCol = Value
            Me.Refresh()
        End Set
    End Property
 
#End Region
 
#Region "Windowprocedure und dazugehörige Sub-Procedures"
 
    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        MyBase.WndProc(m)
 
        Try
            If MyBase.BorderStyle = BorderStyle.FixedSingle Then
                If m.Msg = WM_PAINT Then
                    DrawBorder()
                End If
            End If
        Catch ex As Exception
            Debug.WriteLine("Fehler in WndProc " & ex.Message)
            Debug.WriteLine("StackTrace " & ex.StackTrace)
        End Try
    End Sub
 
    Protected Overridable Sub DrawBorder()
        Dim rcBorder As Rectangle
        Dim hdc As IntPtr
        Dim gr As Graphics
        Dim pen As Pen
 
        hdc = GetDC(Me.Handle)
        gr = Graphics.FromHdc(hdc)
 
        rcBorder = New Rectangle(0, 0, Me.Width - 1, Me.Height - 1)
        pen = New Pen(myBorderCol, 1)
        gr.DrawRectangle(pen, rcBorder)
        pen.Dispose()
        gr.Dispose()
 
        ReleaseDC(Me.Handle, hdc)
 
    End Sub
 
#End Region
 
End Class