Private WithEvents myDoc As mshtml.HTMLDocumentClass

    Private Sub AxWebBrowser1_DocumentComplete( _
        ByVal sender As Object, _
        ByVal e As AxSHDocVw.DWebBrowserEvents2_DocumentCompleteEvent) _
        Handles AxWebBrowser1.DocumentComplete
 
        myDoc = CType(AxWebBrowser1.Document, mshtml.HTMLDocumentClass)
 
    End Sub

    Private Function myDoc_HTMLDocumentEvents2_Event_oncontextmenu( _
        ByVal pEvtObj As mshtml.IHTMLEventObj) _
        As Boolean _
        Handles myDoc.HTMLDocumentEvents2_Event_oncontextmenu
 
        'ACHTUNG: der Event steht erst zur Verfügung, wenn das Dokument 
        'komplett geladen worden ist
        Dim pt As Point
 
        'Umrechnen der Mauskoordinaten des Contextmenu-Events in 
        ' Fensterkoordinaten
        'der Form auf der das Webbrowsercontrol ist
        pt = PointFromHtmlEvent(pEvtObj)
 
        'Nun das Kontextmenu anzeigen
        mnuBrowser.Show(AxWebBrowser1.Parent, pt)
 
        Return False
    End Function

Private Function PointFromHtmlEvent(ByVal pEvtObj As mshtml.IHTMLEventObj) As _
  Point
        'rechnet die Koordinaten eines HtmlEvents in Fensterkoordinaten um
        Dim x%, y%
        Dim el As mshtml.IHTMLElement
        Dim elBody As mshtml.HTMLBodyClass
        Dim ptRet As Point
 
        'Koordinaten relativ zum Source-Element, in dem das 
        'Ereignis stattgefunden hat ermitteln
        x = pEvtObj.offsetX
        y = pEvtObj.offsetY
 
        'Die Koordinaten des Source-Elements relativ
        'zum Body des HTML-Documents ermitteln
        el = pEvtObj.srcElement
        elBody = myDoc.body
        Do
            x = x + el.offsetLeft
            y = y + el.offsetTop
            el = el.offsetParent
            If el Is Nothing Then
                Exit Do
            End If
        Loop Until el Is elBody
 
        'Wenn die Seite gescrollt ist, die Scroll-Weiten wieder
        'von den Koordinaten abziehen
        x = x - elBody.scrollLeft
        y = y - elBody.scrollTop
 
        'zum Schluss die Position des Browsercontrols hinzuaddieren 
        'jetzt hat man die Koordinaten relativ zu dem Control
        'das der Container des Browser-Steuerelements ist
        x = x + AxWebBrowser1.Left
        y = y + AxWebBrowser1.Top
 
        ptRet = New Point(x, y)
        Return ptRet
    End Function

    Private Sub miBrItem01_Click( _
        ByVal sender As Object, _
        ByVal e As System.EventArgs) _
        Handles miBrItem01.Click
 
        Dim mi As MenuItem = CType(sender, MenuItem)
        MsgBox("Klick on " & mi.Text)
    End Sub

    Private Function myDoc_HTMLDocumentEvents2_Event_onclick( _
        ByVal pEvtObj As mshtml.IHTMLEventObj) _
        As Boolean _
        Handles myDoc.HTMLDocumentEvents2_Event_onclick
 
        'Der Event muss rein, weil sonst Klickevents "verschluckt" werden
        'gleiches gilt, so vermute ich, auch für alle anderen Events des 
        ' Document-Objekts
        Return True
    End Function