Public Shared Sub Main()
 
    Dim createdNew As Boolean
 
    ' ID für Mutext - NICHT KOPIEREN, SONDERN NEUE ERZEUGEN
    Dim mutexGuid As String = "{A0330AB0-8961-415a-A13E-86A585925C4C}"
 
    ' Mutex abfragen und ggf. belegen
    Dim mtx As New System.Threading.Mutex(False, mutexGuid, _
      createdNew)
 
    ' War der Mutex bereits angelegt?
    If createdNew Then
 
      ' Nein, das ist die einzige Instanz auf dieser Maschine
      ' Hauptfenster anzeigen
      Application.Run(New MainWindow)
 
    Else
      ' Ja, es läuft bereits eine Instanz
      ' Aktuelle Prozess:
      Dim curProcess As Process = Process.GetCurrentProcess
 
      ' Alle Prozesse mit gleichem Namen abrufen
      Dim processes() As Process = _
        Process.GetProcessesByName(curProcess.ProcessName)
 
      ' Liste durchlaufen (sollte in der Regel zwei Einträge haben)
      For Each p As Process In processes
 
        ' Richtige Applikation?
        If p.MainModule.FileName = curProcess.MainModule.FileName Then
 
          ' Für den ersten fremden Prozess
          If p.Id <> curProcess.Id Then
            ' Hauptfenster dieses Prozesses anzeigen
            API.SetForegroundWindow(p.MainWindowHandle)
 
            ' Wenn es minimiert ist, wiederherstellen
            If API.IsIconic(p.MainWindowHandle) Then
              API.ShowWindow(p.MainWindowHandle, _
                API.ShowWindowConstants.SW_RESTORE)
            Else
              '' Ansonsten unverändert anzeigen
              'API.ShowWindow(p.MainWindowHandle, _
              '  API.ShowWindowConstants.SW_SHOW)
            End If
 
            ' Bearbeitung beenden
            Return
          End If
        End If
      Next
    End If
 
  End Sub