Public MustInherit Class Säugetier
    Private myName$
    Private myIsFemale As Boolean
    Private myAge As Single
 
    Protected Sub New(ByVal name$, ByVal isFemale As Boolean)
        MyBase.New()
        myName = name
        myIsFemale = isFemale
    End Sub
 
    Public ReadOnly Property Name$()
        <DebuggerStepThrough()> Get
            Return myName
        End Get
    End Property
 
    Public ReadOnly Property IsFemale() As Boolean
        <DebuggerStepThrough()> Get
            Return myIsFemale
        End Get
    End Property
 
    Public Sub SäugeJungtier(ByVal jungTier As Säugetier)
        If Not myIsFemale Then
            Throw New ApplicationException("Männchen können nicht säugen.")
        End If
 
        Console.WriteLine("Säugetier """ & Me.Name _
                          & """ ernährt Jungetier """ & jungTier.Name & """")
    End Sub
 
End Class
 
 
Public Class Wolf
    Inherits Säugetier
 
    Public Sub New(ByVal name$, ByVal isFemale As Boolean)
        MyBase.New(name, isFemale)
    End Sub
 
    Public Shadows Sub SäugeJungtier(ByVal jungWolf As Säugetier)
        If TypeOf jungWolf Is Wolf Then
            MyBase.SäugeJungtier(jungWolf)
        Else
            Console.WriteLine("Der Wolf """ & Me.Name & _
                              """ frisst " & jungWolf.Name)
        End If
 
    End Sub
End Class
 
 
Public Class Mensch
    Inherits Säugetier
 
    Public Sub New(ByVal name$, ByVal isFemale As Boolean)
        MyBase.New(name, isFemale)
    End Sub
 
End Class
 
Public Class Starter
    Public Shared Sub Main()
        Dim wölfin As New Wolf("Wölfin", True)
        Dim wolfsjunges As New Wolf("Wolfsjunges", True)
        Dim romulus As New Mensch("Romulus", False)
        Dim remus As New Mensch("Remus", False)
        Dim drapondur As New Mensch("Drapondur", True)
 
        wölfin.SäugeJungtier(wolfsjunges)
        wölfin.SäugeJungtier(drapondur) 'Autsch
        CType(wölfin, Säugetier).SäugeJungtier(romulus)
        CType(wölfin, Säugetier).SäugeJungtier(remus)
        Console.ReadLine()
    End Sub
End Class