Imports System.ComponentModel
Imports System.Runtime.InteropServices
 
Public Class Browser
    Inherits WebBrowser
 
    Private _cookieEvents As AxHost.ConnectionPointCookie
    Private WithEvents _browserEvents As DWebBrowserEvents2Impl
 
    Protected Overrides Sub CreateSink()
        MyBase.CreateSink()
        _browserEvents = New DWebBrowserEvents2Impl
        _cookieEvents = New AxHost.ConnectionPointCookie(Me.ActiveXInstance, _
          _browserEvents, GetType(DWebBrowserEvents2))
    End Sub
 
    Protected Overrides Sub DetachSink()
        If Not _cookieEvents Is Nothing Then
            _cookieEvents.Disconnect()
            _cookieEvents = Nothing
        End If
        MyBase.DetachSink()
    End Sub
 
    Private Sub _browserEvents_NewWindow(ByRef pDisp As Object, ByRef cancel As _
      Boolean) Handles _browserEvents.NewWindow
        Dim e As New NewWindowExEventArgs(cancel)
        OnNewWindowEx(e)
        If Not e.NewBrowser Is Nothing Then
            pDisp = e.NewBrowser.ActiveXInstance
        End If
        cancel = e.Cancel
    End Sub
 
 
    Public Class NewWindowExEventArgs
        Inherits CancelEventArgs
        Public Sub New()
            MyBase.New()
        End Sub
        Public Sub New(ByVal cancel As Boolean)
            MyBase.New(cancel)
        End Sub
 
        Private _newBrowser As WebBrowser
        Public Property NewBrowser() As WebBrowser
            Get
                Return _newBrowser
            End Get
            Set(ByVal value As WebBrowser)
                _newBrowser = value
            End Set
        End Property
    End Class
 
    Public Delegate Sub NewWindowExEventHandler(ByVal sender As Object, ByVal e _
      As NewWindowExEventArgs)
    Public Event NewWindowEx As NewWindowExEventHandler
    Protected Overridable Sub OnNewWindowEx(ByVal e As NewWindowExEventArgs)
        RaiseEvent NewWindowEx(Me, e)
    End Sub
 
End Class

    Private Sub Browser1_NewWindowEx(ByVal sender As Object, ByVal e As _
      Browser.NewWindowExEventArgs) Handles Browser1.NewWindowEx
        Dim nbr As New Browser
        e.NewBrowser = nbr
        Me.Panel1.Controls.Remove(Me.Browser1)
        Me.Browser1 = nbr
        nbr.Dock = DockStyle.Fill
        Me.Panel1.Controls.Add(Me.Browser1)
 
    End Sub