Option Strict On
Option Explicit On
 
Imports System.IO
 
Public Class Form1
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles MyBase.Load
 
        ' Den ersten Knoten setzen.
        Dim RootNode As New TreeNode("C:\")
        treeFiles.Nodes.Add(RootNode)
 
        ' Die erste Ebene füllen und öffnen.
        Fill(RootNode)
        treeFiles.Nodes(0).Expand()
 
    End Sub
 
    Private Sub Fill(ByVal dirNode As TreeNode)
 
        Dim Dir As New DirectoryInfo(dirNode.FullPath)
        Dim DirItem As DirectoryInfo
 
        Try
            For Each DirItem In Dir.GetDirectories
                ' Knoten für Verzeichnis hinzufügen.
                Dim NewNode As New TreeNode(DirItem.Name)
                dirNode.Nodes.Add(NewNode)
                NewNode.Nodes.Add("*")
            Next
        Catch Err As UnauthorizedAccessException
            ' Ein Fehler wird ausgelöst, wenn Sie keine Berechtigung besitzen, 
            ' um
            ' auf das Verzeichnis zuzugreifen - ignorieren Sie dies.
        End Try
 
    End Sub

    Private Sub TreeFiles_AfterSelect(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.TreeViewEventArgs) Handles TreeFiles.AfterSelect
        Debug.WriteLine(e.Node.FullPath)
    End Sub

    Private Sub treeFiles_BeforeExpand(ByVal sender As Object, _
    ByVal e As TreeViewCancelEventArgs) Handles TreeFiles.BeforeExpand
 
        ' Überprüfen, ob es sich um den Platzhalterknoten handelt.
        If e.Node.Nodes(0).Text = "*" Then
            ' Deaktiviert das Neuzeichnen.
            treeFiles.BeginUpdate()
 
            e.Node.Nodes.Clear()
            Fill(e.Node)
 
            ' Aktiviert das Neuzeichnen.
            treeFiles.EndUpdate()
        End If
 
    End Sub
 
End Class