Public Class Form1
 
	Friend WithEvents RunButton As System.Windows.Forms.Button
	Friend WithEvents chkExInBegin As System.Windows.Forms.CheckBox
	Friend WithEvents chkExInMethod As System.Windows.Forms.CheckBox
 
	Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)
		MyBase.OnLoad(e)
		'Ein paar Controls zur Form tun
		Me.RunButton = New System.Windows.Forms.Button
		Me.chkExInBegin = New System.Windows.Forms.CheckBox
		Me.chkExInMethod = New System.Windows.Forms.CheckBox
		Me.RunButton.Location = New System.Drawing.Point(12, 57)
		Me.RunButton.Name = "RunButton"
		Me.RunButton.Size = New System.Drawing.Size(75, 23)
		Me.RunButton.Text = "Run"
		Me.chkExInBegin.AutoSize = True
		Me.chkExInBegin.Location = New System.Drawing.Point(12, 12)
		Me.chkExInBegin.Name = "chkExInBegin"
		Me.chkExInBegin.Size = New System.Drawing.Size(114, 17)
		Me.chkExInBegin.Text = "Exception in Begin"
		Me.chkExInMethod.AutoSize = True
		Me.chkExInMethod.Location = New System.Drawing.Point(12, 34)
		Me.chkExInMethod.Name = "chkExInMethod"
		Me.chkExInMethod.Size = New System.Drawing.Size(129, 17)
		Me.chkExInMethod.Text = "Exception in Methode"
		Me.Controls.Add(Me.chkExInMethod)
		Me.Controls.Add(Me.chkExInBegin)
		Me.Controls.Add(Me.RunButton)
	End Sub
 
	Private Sub RunButton_Click(ByVal sender As System.Object, ByVal e As _
  System.EventArgs) _
	 Handles RunButton.Click
		Dim worker As New Worker
		Stop
		worker.ThrowInBegin = chkExInBegin.Checked
		worker.ThrowInMethod = chkExInMethod.Checked
		Try
			worker.BeginMethode(AddressOf CallBack, worker)
		Catch ex As Exception
			Stop
			MsgBox(ex.ToString)
		End Try
	End Sub
 
	Private Sub CallBack(ByVal ar As IAsyncResult)
		Try
			Stop
			Dim worker As Worker = CType(ar.AsyncState, Worker)
			Dim ret As String = worker.EndMethode(ar)
			MsgBox("Return Value " & ret)
		Catch ex As Exception
			Stop
			MsgBox(ex.ToString)
		End Try
	End Sub
 
End Class
 
Public Class Worker
	Public ThrowInBegin As Boolean
	Public ThrowInMethod As Boolean
 
	Private Delegate Function MethodenDele() As String
 
	Public Function Methode() As String
		Stop
		If ThrowInMethod Then
			'Hier wird im Debugmodus das komische Hinweisfenster
			'aufgehen. Einfach mit F5 oder F8/F11 weitermachen.
			Throw New ApplicationException("Exception aus Methode selbst")
		End If
		Return "Methode aufgerufen"
	End Function
 
	Public Function BeginMethode(ByVal cb As AsyncCallback, ByVal args As Object) _
  As IAsyncResult
		Stop
		If ThrowInBegin Then
			Throw New ApplicationException("Exception aus BeginMethode")
		End If
 
		Dim d As New MethodenDele(AddressOf Methode)
		Return d.BeginInvoke(cb, args)
	End Function
 
	Public Function EndMethode(ByVal ar As IAsyncResult) As String
		Try
			Stop
			Dim oAr As Runtime.Remoting.Messaging.AsyncResult
			oAr = CType(ar, Runtime.Remoting.Messaging.AsyncResult)
			Dim d As MethodenDele
			d = CType(oAr.AsyncDelegate, MethodenDele)
			Return d.EndInvoke(ar)
		Catch ex As Exception
			Stop
			Throw
		End Try
	End Function
 
End Class