Public Class frmPics
 
    Dim pblist As New List(Of PictureBox) 'Liste der Pictureboxen
    Dim total As Bitmap 'Gesamtbitmap
 
    Private Sub frmPics_Load(ByVal sender As System.Object, _
                             ByVal e As System.EventArgs) Handles MyBase.Load
 
        'Größe der Pictureboxen
        Dim picWidth As Integer = 50
        Dim picHeight As Integer = 60
 
        'Erstellung und Positionierung der Pictureboxen
        For i As Integer = 0 To picWidth * 4 Step picWidth
            For k As Integer = 0 To picHeight * 5 Step picHeight
                Dim pbox As New PictureBox With {.Parent = Me, _
                .Top = k, .Left = i, .Width = picWidth, .Height = picHeight}
 
                Using bmp As New Bitmap(picWidth, picHeight),
                    gr As Graphics = Graphics.FromImage(bmp)
                    Dim gray As Integer = 25 * i \ picWidth + 25 * k \ picHeight
                    gr.Clear(Drawing.Color.FromArgb(gray, gray, gray))
                    pbox.Image = CType(bmp.Clone, Bitmap)
                End Using
 
                pblist.Add(pbox)
            Next k
        Next i
 
        'Gesamtbitmap
        total = New Bitmap(picWidth * 5, picHeight * 6)
 
        FillTotal()  'Picturebox-Images in Gesamtbitmap eintragen
 
        DrawSomething() 'in Gesamtbitmap zeichnen
 
        FillList() 'Gesamtbitmap in Pictureboxen übertragen
 
    End Sub
 
    Private Sub FillTotal()
        Using gr As Graphics = Graphics.FromImage(total)
            For i As Integer = 0 To pblist.Count - 1
                With pblist(i)
                    gr.DrawImage(.Image, .Left, .Top, .Width, .Height)
                End With
            Next i
        End Using
    End Sub
 
    Private Sub FillList()
        For i As Integer = 0 To pblist.Count - 1
            With pblist(i)
                Using gr As Graphics = Graphics.FromImage(.Image)
                    Dim destrect As New Rectangle(0, 0, .Width, .Height)
                    Dim srcrect As New Rectangle(.Left, .Top, .Width, .Height)
                    gr.DrawImage(total, destrect, srcrect, GraphicsUnit.Pixel)
                End Using
            End With
        Next i
    End Sub
 
    Private Sub DrawSomething()
 
        Using gr As Graphics = Graphics.FromImage(total), _
            redpen As New Pen(Color.Red, 3),
            redbrush As New SolidBrush(Color.Red)
            With total
                gr.DrawEllipse(redpen, 10, 10, .Width - 20, .Height - 20)
                gr.DrawString _
                ("Ich wünsche allen " & vbNewLine & "ein gutes Neues Jahr", _
                New Font("Arial", 14), redbrush, 30, total.Height \ 2)
            End With
        End Using
    End Sub
 
End Class