''' <summary>
''' Allgemeiner Designer fuer zusammengesetzte UserControls mit mehreren 
' exportierten Snaplines 
''' </summary>
''' <remarks></remarks>
Public Class UserControlCustomDesigner
 
    Inherits System.Windows.Forms.Design.ControlDesigner
 
    Public Overloads Overrides ReadOnly Property SnapLines() As IList
        Get
 
            'SnapLines aus der Basisklasse 
            Dim SnapLinesExtended As IList = MyBase.SnapLines
 
            'Untersuche ob diejenige Klasse zu welcher der Designer gehoert auf 
            ' das Interface SnapLinesProvider zu casten 
            Dim SnapLinesProvider As ISnapLinesProvider = TryCast(Me.Control, _
              ISnapLinesProvider)
 
            If SnapLinesProvider Is Nothing Then
            Else
 
                'Gehe ueber alle SnpaableControls aus dem Basiscontrol drueber   
                For Each Control As Control In _
                  SnapLinesProvider.SnapableControls
 
                    'Versuche je Control den Designer zu finden 
                    Dim Designer As IDesigner = TypeDescriptor.CreateDesigner( _
                      Control, GetType(IDesigner))
 
                    If Designer Is Nothing Then
                    Else
 
                        'Initialisiere den Designer 
                        Designer.Initialize(Control)
 
                        Using Designer
 
                            Dim BoxDesigner As ControlDesigner = TryCast( _
                              Designer, ControlDesigner)
 
                            If BoxDesigner Is Nothing Then
                            Else
 
                                For Each Line As SnapLine In _
                                  BoxDesigner.SnapLines
                                    If Line.SnapLineType = _
                                    SnapLineType.Baseline Then
 
                                        'Nimm die bestehende SnapLine / 
                                        ' BaseLine eines Untercontrols aus dem 
                                        ' UserControl und mache darus eine neue 
                                        'SnapLine bezogen auf das UserControl 
                                        SnapLinesExtended.Add(New SnapLine( _
                                          SnapLineType.Baseline, Line.Offset + _
                                          Control.Top, Line.Filter, _
                                          Line.Priority))
                                        Exit For
                                    End If
                                Next
 
                            End If
 
                        End Using
                    End If
 
                Next
 
            End If
 
            Return SnapLinesExtended
 
        End Get
 
    End Property
End Class