Option Strict On
Imports System.Windows.Forms
Imports System.IO
Imports System.Collections.Generic
Imports System.Threading
Imports System.Diagnostics
Imports System.Runtime.InteropServices
 
 
Public Class MyForm
 
    ' Msg-Typ QueryCancelAutoPlay
    Private ReadOnly msgQueryCancelAutoPlay As Integer
 
    <DllImport("user32.dll", EntryPoint:="RegisterWindowMessageW", _
      SetLastError:=True, CharSet:=CharSet.Unicode, _
      CallingConvention:=CallingConvention.Winapi, ExactSpelling:=True)> _
    Private Shared Function RegisterWindowMessage(lpString As String) As Integer
    End Function
 
    Public Sub New()
        InitializeComponent()
 
        ' QueryCancelAutoPlay-Message registrieren
        msgQueryCancelAutoPlay = RegisterWindowMessage("QueryCancelAutoPlay")
        If msgQueryCancelAutoPlay = 0 Then 'Function failed
            Throw New System.ComponentModel.Win32Exception( _
              Marshal.GetLastWin32Error())
        End If
    End Sub
 
 
    Protected Overrides Sub WndProc(ByRef m As Message)
        Select Case m.Msg
            Case msgQueryCancelAutoPlay 'QueryCancelAutoPlay
                ' Autorun/Autoplay deaktivieren
                m.Result = New IntPtr(1) 'True
            Case Else
                MyBase.WndProc(m)
        End Select
    End Sub
 
End Class